sys-power/power-profiles-daemon: add 0.20

Signed-off-by: Theo Donacik <theodonacik@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35456
Closes: https://bugs.gentoo.org/925437
Closes: https://github.com/gentoo/gentoo/pull/35167
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

sys-power/power-profiles-daemon/Manifest

@@ -1 +1,2 @@
 DIST power-profiles-daemon-0.13.tar.bz2 49079 BLAKE2B 2a7c81b0ac8b4ac4a9805f5dcd722959ff0abe736782eba7678f49eb3c5790d59b2bcc35577733aaae9fc8baa76a65ca9a973ac9f0d9154061c3af86abe0e65d SHA512 dab0c44968480a2f5ae2074f07a48d901970c9b3b3ec104d14108615f85b1eb0f9f3e1b5f0ff766659e4d76b243da2cd4c025cd81b992b7149fb671e103a7d6b
+DIST power-profiles-daemon-0.20.tar.bz2 58388 BLAKE2B f25bc2618441f53624567c4f40d9960b28bf46fb2098eb0e2098207149df3d4923a13c40d781885e37708bf896b537ccb969ec7a928669a3776722e5e58801cf SHA512 2236aac94dafbf6fd951f3bd44953f1a14bc7c5e55349307374d836e20377e1768dcf1250fa8dcf9f01d4eddea8ab64082881189b4e958fbfcd5e2e90d3e823a

sys-power/power-profiles-daemon/power-profiles-daemon-0.20.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 systemd
+
+DESCRIPTION="Makes power profiles handling available over D-Bus"
+HOMEPAGE="https://gitlab.freedesktop.org/upower/power-profiles-daemon/"
+SRC_URI="https://gitlab.freedesktop.org/upower/${PN}/-/archive/${PV}/${P}.tar.bz2"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+IUSE="gtk-doc selinux test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+	dev-libs/glib:2
+	>=dev-libs/libgudev-234
+	>=sys-auth/polkit-0.99
+	sys-power/upower
+	selinux? ( sec-policy/selinux-powerprofiles )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-util/gi-docgen
+		dev-util/gtk-doc
+	)
+	test? (
+		dev-util/umockdev
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	else
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/powerprofilesctl
+	newinitd "${FILESDIR}/power-profiles-daemon.initd" power-profiles-daemon
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "You need to enable the service:"
+		if systemd_is_booted; then
+			elog "# systemctl enable ${PN}"
+		else
+			elog "# rc-update add ${PN} default"
+		fi
+	fi
+}