net-misc/connman: bump to 1.37

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

net-misc/connman/Manifest

@@ -1,2 +1,3 @@
 DIST connman-1.35.tar.xz 686092 BLAKE2B 706d8333dc2fcbee8d0ef3849325c4975dfe312a7a542ee96859a1724e05b1302c244a0108ab70033b398301c235fb13cb9509e9147dc2bb049e900f3799cd98 SHA512 2234b4d18b038f9a33939035cddebd31c74ce962e5616c2c30b2912476612ef3f7d5b9edca64bf6e69fa358252ed432124e036ac3516b291b86695cb9a96c6a8
 DIST connman-1.36.tar.xz 692616 BLAKE2B 7d8cea55365fbfe78cd897b5b65d8edf475a737220732c46c95dda4c6b12badddca38150dbedddcc95c29bce486d86fe130a9d65043c6e18ed6b1eba3fe5aec0 SHA512 c0b9e924a28d58539d44c314168ae7aa46dfea8ce9d125198f525a6d6ef95ca77fd0357c4c4c7548b362b9de8e6f85c7915b1a4cf89b65116c4cbc4df75318e1
+DIST connman-1.37.tar.xz 707752 BLAKE2B ad8993764a444d205b0a8cf1ad38acc249a1a28014e6f4e5a89c8662194ad2e2ee6091b51445b88a885808461413b3aaf88eeb7b75a32f417b578d2da80a2e9f SHA512 5d5363105aedd0c9d609dd5c64eb832d9ff80923a944d9d3738337a61f180ded227f2ae1ff7912bed8826b35f0cfd20488e3ffd3801f0e53e90f98498e19efb6

net-misc/connman/connman-1.37.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+inherit autotools systemd tmpfiles
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://01.org/connman"
+SRC_URI="mirror://kernel/linux/network/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+IUSE="${IUSE} bluetooth debug doc examples +ethernet iptables iwd l2tp nftables"
+IUSE="${IUSE} ofono openvpn openconnect pptp policykit tools vpnc +wifi wispr networkmanager"
+
+REQUIRED_USE="|| ( iptables nftables )"
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	sys-libs/readline:0=
+	iptables? ( >=net-firewall/iptables-1.4.8 )
+	bluetooth? ( net-wireless/bluez )
+	iwd? ( net-wireless/iwd )
+	l2tp? ( net-dialup/xl2tpd )
+	nftables? (
+		>=net-libs/libnftnl-1.0.4:0=
+		>=net-libs/libmnl-1.0.0:0= )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-vpn/openconnect )
+	openvpn? ( net-vpn/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-vpn/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39
+	virtual/pkgconfig"
+
+#PATCHES=(
+#	"${FILESDIR}/${PN}-1.33-polkit-configure-check-fix.patch"
+#)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--with-systemdunitdir=$(systemd_get_systemunitdir) \
+		--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable examples test) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable iwd) \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wispr wispr builtin) \
+		$(use_enable debug) \
+		$(use_enable tools) \
+		$(use_enable networkmanager nmcompat) \
+		--with-firewall=$(usex iptables "iptables" "nftables" ) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /usr/lib/${PN}/scripts
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
+
+pkg_postinst() {
+	tmpfiles_process /usr/lib/tmpfiles.d/connman_resolvconf.conf
+}