dev-util/intel-graphics-compiler: add 1.0.12504.5

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-util/intel-graphics-compiler/Manifest

@@ -1 +1,2 @@
 DIST intel-graphics-compiler-1.0.12260.1.tar.gz 8887984 BLAKE2B 626b5f2bd189ba9b2933b9d65227ca1552484f73f7398b2a763744d21a4ea189987e4eb08e9e7f09898fb49568b59a2c45298363495c1759fec9927a95cf4478 SHA512 4223e9c8213c7e6cf3539d955394a0a4a39cb8d2114ce18ccaeeb0b36a91ca6fc6a314fa9d9db24929fa7cd6b86ff8b82f369f35dd80e5df49b23ac9cd3a519b
+DIST intel-graphics-compiler-1.0.12504.5.tar.gz 8941924 BLAKE2B 6441cc50c2449524c800c73736f8963bc0011c6b87eefa03575cf09d00a8e812c9961bd50fb9801b77452da2d993e76196beb0a2093a249a87d7182e1c1e8707 SHA512 32a94b213a591f9ceb8ca08674c9fb8994b50818c51a6bfd412c4cd30bb9433b938eb7b49ba0afac9f2900a3dcbc7dd79e3e66fb444c7fd5723b6b50c5d1ab89

dev-util/intel-graphics-compiler/intel-graphics-compiler-1.0.12504.5.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+LLVM_MAX_SLOT="14"
+MY_PN="igc"
+MY_P="${MY_PN}-${PV}"
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake flag-o-matic llvm python-any-r1
+
+DESCRIPTION="LLVM-based OpenCL compiler for OpenCL targetting Intel Gen graphics hardware"
+HOMEPAGE="https://github.com/intel/intel-graphics-compiler"
+SRC_URI="https://github.com/intel/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug"
+
+DEPEND="
+	dev-libs/opencl-clang:${LLVM_MAX_SLOT}=
+	dev-util/spirv-tools
+	sys-devel/lld:${LLVM_MAX_SLOT}=
+	sys-devel/llvm:${LLVM_MAX_SLOT}=
+"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="
+	=sys-devel/lld-${LLVM_MAX_SLOT}*
+	${PYTHON_DEPS}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.9-no_Werror.patch"
+	"${FILESDIR}/${PN}-1.0.8173-opencl-clang_version.patch"
+	"${FILESDIR}/${PN}-1.0.8365-disable-git.patch"
+	"${FILESDIR}/${PN}-1.0.11485-include-opencl-c.patch"
+)
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# Get LLVM version
+	local llvm_version="$(best_version -d sys-devel/llvm:${LLVM_MAX_SLOT})"
+	local llvm_version="${llvm_version%%-r*}"
+
+	# See https://github.com/intel/intel-graphics-compiler/issues/212
+	append-ldflags -Wl,-z,undefs
+
+	# See https://bugs.gentoo.org/718824
+	! use debug && append-cppflags -DNDEBUG
+
+	local mycmakeargs=(
+		-DCCLANG_INCLUDE_PREBUILDS_DIR="/usr/lib/clang/${llvm_version##*-}/include"
+		-DCCLANG_SONAME_VERSION="${LLVM_MAX_SLOT}"
+		-DCMAKE_LIBRARY_PATH="$(get_llvm_prefix ${LLVM_MAX_SLOT})/$(get_libdir)"
+		-DIGC_OPTION__ARCHITECTURE_TARGET="Linux64"
+		-DIGC_OPTION__CLANG_MODE="Prebuilds"
+		-DIGC_OPTION__LINK_KHRONOS_SPIRV_TRANSLATOR="ON"
+		-DIGC_OPTION__LLD_MODE="Prebuilds"
+		-DIGC_OPTION__LLDELF_H_DIR="${EPREFIX}/usr/include/lld/Common"
+		-DIGC_OPTION__LLVM_MODE="Prebuilds"
+		-DIGC_OPTION__LLVM_PREFERRED_VERSION="${llvm_version##*-}"
+		-DIGC_OPTION__SPIRV_TOOLS_MODE="Prebuilds"
+		-DIGC_OPTION__SPIRV_TRANSLATOR_MODE="Prebuilds"
+		-DIGC_OPTION__USE_PREINSTALLED_SPRIV_HEADERS="ON"
+		-DINSTALL_GENX_IR="ON"
+		-DSPIRVLLVMTranslator_INCLUDE_DIR="${EPREFIX}/usr/lib/llvm/${LLVM_MAX_SLOT}/include/LLVMSPIRVLib"
+		-Wno-dev
+
+		# Compilation with VectorCompiler causes currently a segfault.
+		# See https://github.com/intel/intel-graphics-compiler/issues/236
+		-DIGC_BUILD__VC_ENABLED="OFF"
+		# -DIGC_OPTION__VC_INTRINSICS_MODE="Prebuilds"
+	)
+
+	cmake_src_configure
+}