gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-11-09 18:47:16 -08:00
Code Issues Projects Releases Wiki Activity

media-libs/libaom: add 3.3.0

Browse Source 
Bug: https://bugs.gentoo.org/833581
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2022-02-18 00:24:08 +00:00
parent 135cf43317
commit 7dfca15ce0
3 changed files with 85 additions and 4 deletions
Download Patch File Download Diff File Expand all files Collapse all files
media-libs/libaom/Manifest
+1
View File
@@ -1 +1,2 @@
DIST libaom-3.2.0.tar.gz 4717955 BLAKE2B b247c9092bf3b8080b33671f182b10eea060a2eafd94eeb1b92177d2c7b5c32de2342f9cf1c7e500b28fdac2b00ea8d43b1e56c9d1c8c0efe1bbc4e40285a52a SHA512 649bebde85c1a42b0c1c3d2d3b7110b999e3ee1c8e76595259e4e75a8b0f3918e23ff7c7e2c313da4d579882f55bf29765bb882570280adc81f3bc1e82f1ee19
DIST libaom-3.3.0.tar.gz 4768475 BLAKE2B 22060694019bcd925cb38c365063b8f2be60aed4cc6f9b0aa95cf8b4c4c5b40f5c603359d8c0728c5650fe9f7eea7573b8fd4a93975481c67409b201b4c48428 SHA512 9bd118bf46d777da4e85f348fed95510ce583d16d005d062d33e2899f16f24bdb8b120792a7c77ccb64b4e1ff5b3d934342fb1b356bb426693ef69220f138c5f
media-libs/libaom/libaom-3.3.0.ebuild
+82
View File
@@ -0,0 +1,82 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake-multilib python-any-r1
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
else
SRC_URI="https://storage.googleapis.com/aom-releases/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
fi
DESCRIPTION="Alliance for Open Media AV1 Codec SDK"
HOMEPAGE="https://aomedia.org https://aomedia.googlesource.com/aom/"
LICENSE="BSD-2"
SLOT="0/3"
IUSE="doc +examples"
IUSE="${IUSE} cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3"
IUSE="${IUSE} cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2"
IUSE="${IUSE} cpu_flags_arm_neon"
REQUIRED_USE="
cpu_flags_x86_sse2? ( cpu_flags_x86_mmx )
cpu_flags_x86_ssse3? ( cpu_flags_x86_sse2 )
"
BDEPEND="${PYTHON_DEPS}
abi_x86_32? ( dev-lang/yasm )
abi_x86_64? ( dev-lang/yasm )
abi_x86_x32? ( dev-lang/yasm )
doc? ( app-doc/doxygen )
"
# the PATENTS file is required to be distributed with this package, bug #682214
DOCS=( PATENTS )
multilib_src_configure() {
local mycmakeargs=(
-DENABLE_CCACHE=OFF
-DENABLE_DOCS=$(multilib_native_usex doc ON OFF)
-DENABLE_EXAMPLES=$(multilib_native_usex examples ON OFF)
-DENABLE_NASM=OFF
-DENABLE_TESTS=OFF
-DENABLE_TOOLS=ON
-DENABLE_WERROR=OFF
# Needs libjxl, currently unpackaged.
-DCONFIG_TUNE_BUTTERAUGLI=0
# neon support is assumed to be always enabled on arm64
-DENABLE_NEON=$(usex cpu_flags_arm_neon ON $(usex arm64 ON OFF))
# ENABLE_DSPR2 / ENABLE_MSA for mips
-DENABLE_MMX=$(usex cpu_flags_x86_mmx ON OFF)
-DENABLE_SSE=$(usex cpu_flags_x86_sse ON OFF)
-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)
-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)
-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)
-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1 ON OFF)
-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2 ON OFF)
-DENABLE_AVX=$(usex cpu_flags_x86_avx ON OFF)
-DENABLE_AVX2=$(usex cpu_flags_x86_avx2 ON OFF)
)
cmake_src_configure
}
multilib_src_install() {
if multilib_is_native_abi && use doc ; then
local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
fi
cmake_src_install
}
multilib_src_install_all() {
find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
}
media-libs/libaom/libaom-9999.ebuild
+2 -4
View File
@@ -3,7 +3,6 @@
EAPI=8
CMAKE_ECLASS=cmake
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake-multilib python-any-r1
@@ -12,12 +11,11 @@ if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
else
SRC_URI="https://storage.googleapis.com/aom-releases/${P}.tar.gz"
S="${WORKDIR}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
fi
DESCRIPTION="Alliance for Open Media AV1 Codec SDK"
HOMEPAGE="https://aomedia.org"
HOMEPAGE="https://aomedia.org https://aomedia.googlesource.com/aom/"
LICENSE="BSD-2"
SLOT="0/3"
@@ -38,7 +36,7 @@ BDEPEND="${PYTHON_DEPS}
doc? ( app-doc/doxygen )
"
# the PATENTS file is required to be distributed with this package bug #682214
# the PATENTS file is required to be distributed with this package, bug #682214
DOCS=( PATENTS )
multilib_src_configure() {