gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

app-alternatives/gzip: Add a package for gzip symlinks

Browse Source 
Closes: https://bugs.gentoo.org/868648
Signed-off-by: Michał Górny <mgorny@gentoo.org>
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Michał Górny
2022-12-01 17:11:04 +01:00
committed by Sam James
parent 9eb1308fb2
commit 7dbd9efce6
2 changed files with 65 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

45
app-alternatives/gzip/gzip-0.ebuild Normal file
View File

@@ -0,0 +1,45 @@
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DESCRIPTION="gzip symlinks"
HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Base/Alternatives"
SRC_URI=""
S=${WORKDIR}
LICENSE="CC0-1.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="pigz +reference split-usr"
REQUIRED_USE="^^ ( pigz reference )"
RDEPEND="
pigz? ( app-arch/pigz[-symlink(-)] )
reference? ( >=app-arch/gzip-1.12-r3 )
!<app-arch/gzip-1.12-r3
!app-arch/pigz[symlink(-)]
"
src_install() {
local usr_prefix=
use split-usr && usr_prefix=../usr/bin/
if use pigz; then
dosym "${usr_prefix}pigz" /bin/gzip
dosym gzip /bin/gunzip
dosym gzip /bin/zcat
newman - gzip.1 <<<".so pigz.1"
elif use reference; then
dosym gzip-reference /bin/gzip
# gzip uses shell wrappers rather than argv[0]
dosym gunzip-reference /bin/gunzip
dosym zcat-reference /bin/zcat
newman - gzip.1 <<<".so gzip-reference.1"
else
die "Invalid USE flag combination (broken REQUIRED_USE?)"
fi
newman - gunzip.1 <<<".so gzip.1"
newman - zcat.1 <<<".so gzip.1"
}

20
app-alternatives/gzip/metadata.xml Normal file
View File

@@ -0,0 +1,20 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>base-system@gentoo.org</email>
<name>Gentoo Base System</name>
</maintainer>
<maintainer type="person">
<email>mgorny@gentoo.org</email>
<name>Michał Górny</name>
</maintainer>
<use>
<flag name="pigz">
Symlink to <pkg>app-arch/pigz</pkg>.
</flag>
<flag name="reference">
Symlink to <pkg>app-arch/gzip</pkg>.
</flag>
</use>
</pkgmetadata>