gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-21 09:07:26 -08:00
Code Issues Projects Releases Wiki Activity

kde-apps/kalarm: 25.12.0 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner 2025-12-11 19:35:59 +01:00
parent 251284d300
commit 7d9881b67a
No known key found for this signature in database
GPG Key ID: AE591BBC73E4DD5E
2 changed files with 87 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/kalarm/Manifest
View File

@ -1 +1,2 @@
DIST kalarm-25.08.3.tar.xz 2690300 BLAKE2B 619ec66ebe93c02509a2164422f1a85f22060955fa44d37d4d1a6ca79451222968228ffec597b5fc59f466564531cffe3bed2514b6cfacc13d7e555a6ac77002 SHA512 9843f2f9881abf7a81a03344443bf28d7973be442d6838151f17fe6b919e2a123b371bd12a511dcfdf196ccee946a4618870b6f29dd217c9462c75e90ee88a28
DIST kalarm-25.12.0.tar.xz 2700024 BLAKE2B 0bfabf7cff551263dbe27bdb7fa2787d7534398fbe6314e982226850222e0c16727a5f3e7c07111014f34bfe05f6bf2368b4f8d1f26f5ff59d886b7aa7faa35a SHA512 81e4b436a917c156f284194291034398a8cf73e9d95c384f6668bac326d9ad7211f7fed3f0d4809863bb46e274af5737fda290b68f379b0efcff8a7ff504ac3c

86
kde-apps/kalarm/kalarm-25.12.0.ebuild Normal file
View File

@ -0,0 +1,86 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
PVCUT=$(ver_cut 1-3)
KFMIN=6.19.0
QTMIN=6.9.1
inherit ecm gear.kde.org xdg
DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
SLOT="6"
KEYWORDS="~amd64 ~arm64"
IUSE="mpv +pim speech X"
COMMON_DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
>=kde-apps/kcalutils-${PVCUT}:6=
>=kde-apps/kidentitymanagement-${PVCUT}:6=
>=kde-apps/kmime-${PVCUT}:6=
>=kde-frameworks/kauth-${KFMIN}:6
>=kde-frameworks/kcalendarcore-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcontacts-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kholidays-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/knotifyconfig-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
>=kde-frameworks/kxmlgui-${KFMIN}:6
mpv? ( >=media-video/mpv-0.37.0:=[libmpv] )
!mpv? ( media-video/vlc:= )
pim? (
>=kde-apps/akonadi-${PVCUT}:6=
>=kde-apps/akonadi-contacts-${PVCUT}:6=
>=kde-apps/akonadi-mime-${PVCUT}:6=
>=kde-apps/kmailtransport-${PVCUT}:6=
)
speech? ( >=dev-libs/ktextaddons-1.8.0:6[speech] )
X? ( x11-libs/libX11 )
"
RDEPEND="${COMMON_DEPEND}
pim? ( =kde-apps/kdepim-runtime-${PVCUT}*:6 )
"
DEPEND="${COMMON_DEPEND}
X? ( x11-base/xorg-proto )
"
src_configure() {
local mycmakeargs=(
-DENABLE_LIBMPV=$(usex mpv)
-DENABLE_LIBVLC=$(usex !mpv)
-DENABLE_AKONADI_PLUGIN=$(usex pim)
$(cmake_use_find_package speech KF6TextEditTextToSpeech)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}
src_test() {
# LC_TIME bug 665626, 857012
# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
LC_TIME="C" TZ=UTC ecm_src_test
}