sci-geosciences/gtk-g-rays2: update EAPI 7 -> 8, fix build on musl

Closes: https://bugs.gentoo.org/832766
Closes: https://bugs.gentoo.org/891835
Closes: https://bugs.gentoo.org/898174
Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com>
Closes: https://github.com/gentoo/gentoo/pull/41553
Signed-off-by: Sam James <sam@gentoo.org>

sci-geosciences/gtk-g-rays2/files/gtk-g-rays2-2.05-missing-include.patch

@@ -0,0 +1,13 @@
+Missing include on musl - transitively included on glibc
+https://bugs.gentoo.org/898174
+https://bugs.gentoo.org/832766
+--- a/src/wbt201.c
++++ b/src/wbt201.c
+@@ -36,6 +36,7 @@
+ #include <errno.h>
+ #include <gdk/gdkkeysyms.h>
+ #include <math.h>
++#include <locale.h>
+ 
+ #define DEFDEVS "[g-rays2]\ndevices = auto;bluetooth;/dev/ttyUSB0\n"
+ 

sci-geosciences/gtk-g-rays2/gtk-g-rays2-2.05-r1.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools gnome2
+
+DESCRIPTION="GUI for accessing the Wintec WBT 201 / G-Rays 2 GPS device"
+HOMEPAGE="http://www.daria.co.uk/gps"
+SRC_URI="http://www.zen35309.zen.co.uk/gps/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/dbus-glib
+	dev-libs/glib:2
+	dev-libs/libgudev
+	net-wireless/bluez
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	virtual/freedesktop-icon-theme"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	dev-util/intltool"
+
+PATCHES=( "${FILESDIR}/${P}-missing-include.patch" )
+
+src_prepare() {
+	default
+
+	# werror is bad idea
+	sed -i -e 's:-Werror::g' configure.ac || die
+	# we run this ourselves
+	sed -i -e '/gtk-update-icon-cache/d' Makefile.am || die
+	eautoreconf
+}