kde-apps/cantor: drop 24.08.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/cantor/Manifest

@@ -1,3 +1,2 @@
 DIST cantor-24.05.2.tar.xz 9196572 BLAKE2B fbc2f3a0bd1b527f5a487043ab2c785efd72c81786612abd402d6c6535a38619151741649453788b9243306d282920bf577ff3c8bc0765e1749ce970bf1b85b4 SHA512 de5631ce3723a4853d8cb1a6d3a9eb9ccdd50218d653b4afb9a5b8fdf19e46dc219b921c214f9b99be180e2c800e96382c7897bf9d6175043b6d464b8073137a
-DIST cantor-24.08.0.tar.xz 10846196 BLAKE2B 5a53830fd6be23ed15a9b4918a3b6d03e72a02163fc4634e39683fd3f070129ff674a4706f7f9b554eacd6a9f780fa603c4b63118b7258c0e9d24c47ae24f7fc SHA512 e5e57a67d3b2462cb9da0728c708321e11b2ac2aee8116b008067c0ceda0dd94f93d70ae8a0ccd9f51f3cefb094cf7c9cf1d9d96fd092e45d585d1efafef311a
 DIST cantor-24.08.1.tar.xz 10847628 BLAKE2B 03793dd5ba9765b188d30e527130d341b92ca76345bbc7bbc7d8e597ebd47c97824536042f80406667a8821bafee24dc20f0cffbec493ab460ce8e40751fd0ee SHA512 8479b044118229445a8183b4c56428279a7616fe7f283c3fec5278b5c8bf97df456012acdbaefe6304a0e838a01377c8c75ea28def09b88eb3a6de3933ad9248

kde-apps/cantor/cantor-24.08.0.ebuild

@@ -1,117 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{10..12} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=5.115.0
-QTMIN=5.15.12
-inherit ecm gear.kde.org lua-single optfeature python-single-r1
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/ https://edu.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~x86"
-# TODO: restore +analitza once cantor is ported to Qt6
-IUSE="julia lua postscript python qalculate R"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-# analitza? ( >=kde-apps/analitza-23.08.4:5 )
-DEPEND="
-	app-text/poppler[qt5]
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qthelp-${QTMIN}:5
-	>=dev-qt/qtprintsupport-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=dev-qt/qtxmlpatterns-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
-	julia? ( dev-lang/julia )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	postscript? ( app-text/libspectre )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtdbus-${QTMIN}:5
-	)
-	R? ( dev-lang/R )
-"
-# !analitza?
-RDEPEND="${DEPEND}
-	!julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) )
-"
-BDEPEND="x11-misc/shared-mime-info"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-	ecm_pkg_setup
-}
-
-src_configure() {
-	use julia && addpredict /proc/self/mem # bug 602894
-
-	local mycmakeargs=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_Analitza5=ON
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		-DUSE_LIBSPECTRE=$(usex postscript)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	ecm_src_configure
-}
-
-src_compile() {
-	# -j1 for bug #919576
-	MAKEOPTS="-j1" ecm_src_compile
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	ecm_pkg_postinst
-}