app-crypt/tpm-tools: version bump to 1.3.9.2.

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Salah Coronya <salah.coronya@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/18179
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

app-crypt/tpm-tools/Manifest

@@ -1 +1,2 @@
 DIST tpm-tools-1.3.9.1.tar.gz 482859 BLAKE2B ee915679e23bead04672bf719ce59bb6f20b550be39855b5304caeff554bf54d3cfe9104d464af7762388995e51d2bed0f9bedad83e42146cb7457382d09f4b2 SHA512 63a9c0e761cd890cc0a218de79a9c0169e151aba7824c19bf6b7ec894cf41c4950de1f63bd849aa93a4bdff36cf0fe557bc17113912b6d77f57f2bf1190b6a08
+DIST tpm-tools-1.3.9.2.tar.gz 431930 BLAKE2B bbea3848765d9907c6faa1b5f4a60002e94243040985ce503f392bc8d7392bea41b54317b15fd227b5d73d589cf2c330729532448751d4375484375725310dfa SHA512 b684716c71702140591d89eb03d3724ed5b448e7ba2881bc44de9d44ffc23a9f7dfcf4351eec24e5438cc883f49a7dafee82bb19f90800610cf764ce74e60ccb

app-crypt/tpm-tools/tpm-tools-1.3.9.2.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="TrouSerS' support tools for the Trusted Platform Modules"
+HOMEPAGE="http://trousers.sourceforge.net"
+SRC_URI="mirror://sourceforge/trousers/${PN}/${P}.tar.gz"
+
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~s390 ~x86"
+IUSE="libressl nls pkcs11 debug"
+
+DEPEND=">=app-crypt/trousers-0.3.0
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	pkcs11? ( dev-libs/opencryptoki )"
+RDEPEND="${DEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	default
+
+# upstream didn't generate the tarball correctly so we must bootstrap
+# ouselves
+	mkdir -p po || die
+	mkdir -p m4 || die
+	cp -R po_/* po/ || die
+	touch po/Makefile.in.in || die
+	touch m4/Makefile.am || die
+
+	sed -i -r \
+		-e '/CFLAGS/s/ -m64//' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	append-cppflags $(usex debug -DDEBUG -DNDEBUG)
+
+	econf \
+		$(use_enable nls) \
+		$(use pkcs11 || echo --disable-pkcs11-support)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}