app-text/crqt-ng: minor improvement

Signed-off-by: Andrey Grozin <grozin@gentoo.org>

app-text/crqt-ng/crqt-ng-1.0.3-r1.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="bg cs hu ru uk"
+inherit cmake plocale xdg
+
+DESCRIPTION="Cross-platform e-book reader"
+HOMEPAGE="https://gitlab.com/coolreader-ng/crqt-ng"
+SRC_URI="https://gitlab.com/coolreader-ng/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gif +svg +chm +harfbuzz +libunibreak +fribidi +zstd +libutf8proc"
+
+CDEPEND=">=app-text/crengine-ng-0.9.3[png,jpeg,fontconfig,gif=,svg=,chm=,harfbuzz=,fribidi=,zstd=,libutf8proc=]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5"
+RDEPEND="${CDEPEND}"
+BDEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5"
+
+PATCHES=( "${FILESDIR}"/${P}-typo.patch )
+
+src_prepare() {
+	cmake_src_prepare
+	xdg_environment_reset
+
+	# locales
+	plocale_find_changes "${S}"/src/i18n 'crqt_' '.ts'
+	sed -e "s|set(LANGUAGES .*)|set(LANGUAGES $(plocale_get_locales))|i" \
+		-i "${S}"/src/CMakeLists.txt \
+		|| die "sed CMakeLists.txt failed"
+}
+
+src_configure() {
+	CMAKE_USE_DIR="${S}"
+	CMAKE_BUILD_TYPE="Release"
+	local mycmakeargs=(-DUSE_QT=QT5)
+	cmake_src_configure
+}

app-text/crqt-ng/files/crqt-ng-1.0.3-typo.patch

@@ -0,0 +1,25 @@
+From 90523e75b7e4dbb6e1dbe0ffe41035b9c174c977 Mon Sep 17 00:00:00 2001
+From: Aleksey Chernov <valexlin@gmail.com>
+Date: Sun, 25 Dec 2022 09:36:55 +0400
+Subject: [PATCH] Update src/i18n/crqt_ru.ts: typo fixed
+
+---
+ src/i18n/crqt_ru.ts | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/src/i18n/crqt_ru.ts b/src/i18n/crqt_ru.ts
+index 124dc9c..2d9415f 100644
+--- a/src/i18n/crqt_ru.ts
++++ b/src/i18n/crqt_ru.ts
+@@ -939,7 +939,7 @@
+     <message>
+         <location filename="../mainwindow.ui" line="307"/>
+         <source>Go to the next position in navigation history</source>
+-        <translation>Перейти к следующей позиции і истории навигации</translation>
++        <translation>Перейти к следующей позиции в истории навигации</translation>
+     </message>
+     <message>
+         <location filename="../mainwindow.ui" line="310"/>
+-- 
+2.37.4
+