dev-python/ml-dtypes: Bump to 0.5.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/ml-dtypes/Manifest

@@ -1,2 +1,3 @@
 DIST eigen-7bf2968fed5f246c0589e1111004cb420fcd7c71.tar.bz2 2239233 BLAKE2B 3a7e81c302cb11ae1d6ef9433a9ec41506c1f37d04cfb8744ac3fcf7dbe9430c1b48d7197ca3b8e1f9354398bac3d0dbc3e0599c0b649acd6175e906befe2973 SHA512 29ee89770726e6e0f5135b7fab24649f3e69223caed90d2daa6f0014783e69fe98f0551de49bd4e393d7b7938f2943caf1ed00f3933fa771ac14fae3c63fd5dd
 DIST ml_dtypes-0.5.3.gh.tar.gz 87116 BLAKE2B 85500d3756aa98f9f746bada8932712c00fffc267358d0350ff7f79d79897858485320e998a4b17fa1d26eee0d8e8d26a09105670941dc5629a71f71dc384271 SHA512 7f1e036201e12349710ae9a9825cd575383b72052a7ebabe26a96952ea0f0be9d4e47a928e454644681a5ec5df88d3142e31602f3146ce5eebbe4bdbe9670ae7
+DIST ml_dtypes-0.5.4.gh.tar.gz 88210 BLAKE2B 2f2695105a597e33ca6ec1b622f1d50d6ba027938c5e8d4139790e5f5d38a234b6a2e9f10331909348e66c58c9e172f9e48afc54100aea9c9160a0152485fe94 SHA512 585641b2d4d9ff7b134310ac38484989d85efd3f303cc99fa71b2b693c710f435d4245bb64239b79f823da647e71f477be89d3141fa6aeb775262ea13a4f1bf7

dev-python/ml-dtypes/ml-dtypes-0.5.4.ebuild

@@ -0,0 +1,58 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=${PN/-/_}-${PV}
+EIGEN_CommitId="7bf2968fed5f246c0589e1111004cb420fcd7c71"
+
+DESCRIPTION="A stand-alone implementation of several NumPy dtype extensions"
+HOMEPAGE="
+	https://github.com/jax-ml/ml_dtypes/
+	https://pypi.org/project/ml-dtypes/
+"
+SRC_URI="
+	https://github.com/jax-ml/ml_dtypes/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	https://gitlab.com/libeigen/eigen/-/archive/${EIGEN_CommitId}/eigen-${EIGEN_CommitId}.tar.bz2
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+DEPEND="
+	>=dev-python/numpy-1.21:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	test? (
+		dev-python/absl-py[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	rmdir third_party/eigen || die
+	mv "${WORKDIR}/eigen-${EIGEN_CommitId}" third_party/eigen || die
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	mv ml_dtypes/tests . || die
+	rm -r ml_dtypes || die
+
+	distutils-r1_src_test
+}