dev-python/simsimd: Bump to 6.4.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/simsimd/Manifest

@@ -1 +1,2 @@
 DIST SimSIMD-6.2.1.gh.tar.gz 216348 BLAKE2B 292d952c77dd35b4f0378661155d186102b7dd319d89040f1148bebee660be356e0a23492e3d9ce3646f17f65b1e9bd7ca436131f812eaf11cbcc0ac056bf4d0 SHA512 602aa84e5c16781dc414703d27234ec6dd28c89f708385422012e7afb729254fb1f4803049a7ca77d48eba34f621bff4c9dde1fa42ddbeeb67c843af72071bde
+DIST SimSIMD-6.4.5.gh.tar.gz 219987 BLAKE2B 35ba9c1913727b55c9ced73c7940343c1653bc059c5e289683011c236581362ee3d6ce29626ec29f6eb6d0c2bc0fd85dc2989ed84e4362a81506b7ac7b4c71e3 SHA512 734700ec6b8dc5d6a73999f2b53365740ffc3c24787a02680e9b329a1c63fff61b429591cf168adbb002b85599a84801a28530cf929f7ade40d5ce1770ce334c

dev-python/simsimd/simsimd-6.4.5.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1 toolchain-funcs
+
+MY_P=SimSIMD-${PV}
+DESCRIPTION="Fastest SIMD-Accelerated Vector Similarity Functions for x86 and Arm"
+HOMEPAGE="
+	https://github.com/ashvardanian/SimSIMD/
+	https://pypi.org/project/simsimd/
+"
+# no sdist, as of 4.3.1
+# https://github.com/ashvardanian/SimSIMD/issues/113
+SRC_URI="
+	https://github.com/ashvardanian/SimSIMD/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="openmp"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-repeat[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-check-openmp
+	fi
+}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-check-openmp
+	fi
+}
+
+src_prepare() {
+	sed -i -e '/-O3/d' setup.py || die
+	if ! use openmp; then
+		sed -i -e '/-fopenmp/d' setup.py || die
+	fi
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p repeat scripts/test.py
+}