x11-wm/herbstluftwm: version bump to 0.7.1

Closes: https://bugs.gentoo.org/672200
Closes: https://github.com/gentoo/gentoo/pull/10514

Signed-off-by: Tim Harder <radhermit@gentoo.org>

x11-wm/herbstluftwm/Manifest

@@ -1 +1,2 @@
 DIST herbstluftwm-0.7.0.tar.gz 247469 BLAKE2B 3ee6c4709bd52ad330706aa941fba4372003f6d494759bc0fc87bcf34cffd07a55d5d4b550de13af059d4455ce240e6be3151b8f7563f3fb0d1dc4ef79306c58 SHA512 792e517dff5cfb075b8b5a42b076a7809e983953620212de6d571d3d606c573c83606a0f7694e25d3351c288473f5129191a416fe8977db8438c1016503eacd8
+DIST herbstluftwm-0.7.1.tar.gz 244726 BLAKE2B bdc8b769c3991276f03540024212315310aab4c5980321a3f019d5dc044b862aa606746d968e01bb0d8280b10ecf2f7f300710e2ac5cba46afd3129c316df5ae SHA512 1eb25c6e64bc046fca4b93cb9158515dba793bb14676229cc9c9194660eeccfc0c907ddcc4b15581b9ffb8b7f261ad3e2c8efe60a5d11eeb836208dd289dc199

x11-wm/herbstluftwm/herbstluftwm-0.7.1.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs bash-completion-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/herbstluftwm/herbstluftwm.git"
+	EXTRA_DEPEND="app-text/asciidoc"
+else
+	SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	EXTRA_DEPEND=""
+fi
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="https://herbstluftwm.org/"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="examples xinerama zsh-completion"
+
+CDEPEND=">=dev-libs/glib-2.24:2
+	x11-libs/libX11
+	x11-libs/libXext
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${CDEPEND}
+	app-shells/bash
+	zsh-completion? ( app-shells/zsh )"
+DEPEND="${CDEPEND}
+	${EXTRA_DEPEND}
+	virtual/pkgconfig"
+
+src_compile() {
+	tc-export CC LD CXX
+
+	emake LDXX="$(tc-getCXX)" COLOR=0 VERBOSE= \
+		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
+}
+
+src_install() {
+	dobin herbstluftwm herbstclient
+	dodoc BUGS MIGRATION NEWS README.md
+
+	doman doc/{herbstluftwm,herbstclient}.1
+
+	exeinto /etc/xdg/herbstluftwm
+	doexe share/{autostart,panel.sh,restartpanels.sh}
+
+	insinto /usr/share/xsessions
+	doins share/herbstluftwm.desktop
+
+	newbashcomp share/herbstclient-completion herbstclient
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins share/_herbstclient
+	fi
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/examples
+		doexe scripts/*.sh
+		docinto examples
+		dodoc scripts/README
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}

x11-wm/herbstluftwm/herbstluftwm-9999.ebuild

@@ -33,7 +33,9 @@ DEPEND="${CDEPEND}
 	virtual/pkgconfig"
 
 src_compile() {
-	emake CC="$(tc-getCC)" LD="$(tc-getCC)" COLOR=0 VERBOSE= \
+	tc-export CC LD CXX
+
+	emake LDXX="$(tc-getCXX)" COLOR=0 VERBOSE= \
 		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
 }