dev-python/tornado: Bump to 6.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/tornado/Manifest

@@ -1 +1,2 @@
 DIST tornado-6.4.2.tar.gz 501135 BLAKE2B 875513089ceaa6d1195cd6959e15bfef51cef4a61c55e678e0e60bd1001afa025d452441938a21ad91189d5c4d07c6cf85d0cec0f41e07cf2c4b7b66e0770c25 SHA512 4f4556f0f7db8e13a101254693f92841374114912960d9874948548452cc9b38933292c0e37971fb151a4d9dbcf5ed7563c1505e090a1aef306f1c46f351534d
+DIST tornado-6.5.tar.gz 508968 BLAKE2B 0b7e64292444582c46bf5e9cf36b438adc9c9345757272518e9a96cac33b5ff00c180224b80cb27ece366e5790f384c86f6c870a52faa4fc60cd504fe571d28c SHA512 30c5caa80fcf7d39bee61f58d7940c57cd1834e0f519501dee49b86a3a00122c1a105205a8edb414b39b6088d217e2628fcd9c8c76b1fceddd81ce087aa31f0a

dev-python/tornado/tornado-6.5.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="
+	https://www.tornadoweb.org/
+	https://github.com/tornadoweb/tornado/
+	https://pypi.org/project/tornado/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.3.2-ignore-deprecationwarning.patch"
+)
+
+src_prepare() {
+	# network-sandbox? ipv6?
+	sed -i -e 's:test_localhost:_&:' \
+		tornado/test/netutil_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x ASYNC_TEST_TIMEOUT=60
+	# Avoid time-sensitive tests
+	# https://github.com/tornadoweb/tornado/blob/10974e6ebee80a26a2a65bb9bd715cf858fafde5/tornado/test/util.py#L19
+	local -x TRAVIS=1
+	local -x NO_NETWORK=1
+
+	cd "${T}" || die
+	# TODO: remove --fail-if-logs=false after we fix the pypy bug
+	# https://github.com/pypy/pypy/issues/5271
+	"${EPYTHON}" -m tornado.test.runtests --verbose --fail-if-logs=false ||
+		die "tests failed under ${EPYTHON}"
+}