app-text/coolreader: bump to 3.2.55

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

app-text/coolreader/Manifest

@@ -1 +1,2 @@
 DIST coolreader-3.2.54.tar.gz 13231261 BLAKE2B aac948ab4535238caf0541f25b3fb1332d17aa46dc7b116543d37c4cd5d900f0e7861e1ab745ba455feec236c6dc05fde6faad2f4e378e33441cee7736b22b9f SHA512 11ca3588a3794dcc5c5970dc508ade43e29a9d6db7d8ef01c7f04d7cfad2c50a21f6f333574d057c45c8f6d7eb619b5f0f072b1163327f694dcbdcc4b7539220
+DIST coolreader-3.2.55.tar.gz 13230319 BLAKE2B 1cb414f38b76072f66705370162a28505ba2273282755704bb8ad28a7b0eb2928aba0a929291ae33fdf9ce42b442c4b941740d59f4f329a401470e2fceceef18 SHA512 4eef99c86259642d6a5c3d9eb388a11c27b7438c0f05a055ef61a1df93af567d30fa39790cc5d5b3d10dcaa4b2931a51773f967904ff75f7fff2040f313c09d6

app-text/coolreader/coolreader-3.2.55.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+WX_GTK_VER="3.0-gtk3"
+PLOCALES="bg cs de es hu pl ru uk"
+inherit cmake wxwidgets l10n xdg
+
+CR_PV=$(ver_rs 3 '-')
+SRC_URI="https://github.com/buggins/${PN}/archive/cr${CR_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-cr${CR_PV}"
+
+DESCRIPTION="CoolReader - reader of eBook files (fb2,epub,htm,rtf,txt)"
+HOMEPAGE="https://github.com/buggins/coolreader/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="wxwidgets"
+
+CDEPEND="sys-libs/zlib
+	media-libs/libpng:0
+	virtual/jpeg:0
+	media-libs/freetype
+	dev-libs/fribidi
+	media-libs/fontconfig
+	media-libs/harfbuzz
+	dev-libs/libunibreak
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER} )
+	!wxwidgets? ( dev-qt/qtcore:5 dev-qt/qtgui:5 dev-qt/qtwidgets:5 )"
+BDEPEND="${CDEPEND}
+	!wxwidgets? ( dev-qt/linguist-tools:5 )"
+RDEPEND="${CDEPEND}
+	wxwidgets? ( || ( media-fonts/liberation-fonts media-fonts/corefonts ) )"
+
+src_prepare() {
+	cmake_src_prepare
+	xdg_src_prepare
+
+	# locales
+	l10n_find_plocales_changes "${S}"/cr3qt/src/i18n 'cr3_' '.ts'
+	sed -e "s|SET(LANGUAGES .*)|SET(LANGUAGES $(l10n_get_locales))|" \
+		-i "${S}"/cr3qt/CMakeLists.txt \
+		|| die "sed CMakeLists.txt failed"
+}
+
+src_configure() {
+	CMAKE_USE_DIR="${S}"
+	CMAKE_BUILD_TYPE="Release"
+	if use wxwidgets; then
+		setup-wxwidgets
+		local mycmakeargs=(-D GUI=WX)
+	else
+		local mycmakeargs=(-D GUI=QT5)
+	fi
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if ! use wxwidgets; then
+		mv "${D}"/usr/share/doc/cr3/changelog.gz "${D}"/usr/share/doc/${PF}/ || die "mv changelog.gz failed"
+		rmdir "${D}"/usr/share/doc/cr3 || die "rmdir doc/cr3 failed"
+		gunzip "${D}"/usr/share/doc/${PF}/changelog.gz || die "gunzip changelog.gz failed"
+		gunzip "${D}"/usr/share/man/man1/cr3.1.gz || die "gunzip cr3.1.gz failed"
+	fi
+}