mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
dev-python/typer: Bump to 0.26.2
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST typer-0.24.2.tar.gz 119849 BLAKE2B baa49b38a5d813278cf1cd98b4a354582902e192dd6265b0905f473c998eeccf0a9f6b4fc07a700ab73eb75d1c37f36122c6b1730778c3a18f15ae6cf2dd0b50 SHA512 4e282e616c8ea57665493bb15bbe3e2a6388f974b602c879a16c14c7c07e55960d9808f4af50b78e79149bb3cb9dbd26da397078ebef8264ec7893ba74034014
|
||||
DIST typer-0.25.1.tar.gz 122276 BLAKE2B 08089d17ca0c038806d0dcc5795d5f88cd0e0163697288b5ae003bdfcaf95537ff465874f1bb5510fe84e0ae1f7ea9c68ebe08639253a0575c220b26297abeb2 SHA512 26e9927a82d8e17e8eae370b7235a7481b6d875c77c5600f8390c22a5274b3a0e3abe14d1c2eae93850613bf685555afe67a2e495687328615c65fc8d27bcb7b
|
||||
DIST typer-0.26.2.tar.gz 198991 BLAKE2B 13357d74a2fa79d24ded2da6d6cfb313165c0b1fe231a48a9f1150f07ce2e3db568a098a16123070448ac20f4beaca8d1be65a027b08d54a3a4579c7c6d3086b SHA512 58ed32b61545d546a298434731f90b9e4b5a0eea8e3bd46dd74f862e1788bf3406a1a65eca23c6b2c6d8945203ee1e7297969d927088d4115298ebe70e2cf9ad
|
||||
|
||||
@@ -0,0 +1,68 @@
|
||||
# Copyright 2025-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=pdm-backend
|
||||
PYTHON_COMPAT=( python3_{11..14} )
|
||||
|
||||
inherit distutils-r1 shell-completion pypi
|
||||
|
||||
DESCRIPTION="Build great CLIs. Easy to code. Based on Python type hints"
|
||||
HOMEPAGE="
|
||||
https://typer.tiangolo.com/
|
||||
https://github.com/fastapi/typer/
|
||||
https://pypi.org/project/typer/
|
||||
"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
IUSE="cli"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/annotated-doc-0.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/rich-13.8.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/shellingham-1.3.0[${PYTHON_USEDEP}]
|
||||
cli? ( !dev-lang/erlang )
|
||||
"
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/coverage[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=()
|
||||
EPYTEST_XDIST=1
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_prepare() {
|
||||
distutils-r1_src_prepare
|
||||
|
||||
# LLM crap
|
||||
rm -r typer/.agents || die
|
||||
if ! use cli; then
|
||||
sed -i -e '/typer\.cli/d' pyproject.toml || die
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
# See scripts/tests.sh
|
||||
local -x TERMINAL_WIDTH=3000
|
||||
local -x _TYPER_FORCE_DISABLE_TERMINAL=1
|
||||
local -x _TYPER_RUN_INSTALL_COMPLETION_TESTS=1
|
||||
|
||||
epytest
|
||||
}
|
||||
|
||||
python_install() {
|
||||
if use cli && [[ ! ${COMPLETIONS_INSTALLED} ]]; then
|
||||
local -x _TYPER_COMPLETE_TEST_DISABLE_SHELL_DETECTION=1
|
||||
newbashcomp - typer < <(typer --show-completion bash || die)
|
||||
newzshcomp - typer < <(typer --show-completion zsh || die)
|
||||
newfishcomp - typer < <(typer --show-completion fish || die)
|
||||
COMPLETIONS_INSTALLED=1
|
||||
fi
|
||||
|
||||
distutils-r1_python_install
|
||||
}
|
||||
Reference in New Issue
Block a user