mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
x11-terms/kitty: add 0.26.4
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens
@@ -1,2 +1,4 @@
|
||||
DIST kitty-0.26.3.tar.xz 4730520 BLAKE2B a2d8cccc76eb295256ac420700e941ac9cb0e79c9717a93226cc30db63ab047dcd0be2e11b36b44c7c15daa0b77a451242d32f71024cee724869ba8937b93dd5 SHA512 77a518cd3ec4bb059907f16d01068914951cadbbcf803dcbfae13cc9ce144f65a886d7e986c7191019a0be9ccf902f086c72a24287458d083cbd3fd136d2c589
|
||||
DIST kitty-0.26.3.tar.xz.sig 566 BLAKE2B 6e8e622bec031416b0f591c0b53f53ba874c977511c447ab625f52bc7fca04f1003ca5db4cc4138336f5afc4f729b2b8b6e0f5d77e296033422774665fbd5ba3 SHA512 4a8fd60ca1baa619790909243a620f816c44a28a8d889633c5b433af0f46cd1c92bcbcbbd9db942c385764387958db294cdeb3cdffc0369a79d56f41ccb81b57
|
||||
DIST kitty-0.26.4.tar.xz 4749148 BLAKE2B fe15d2bd3afda49fcdc911d0ada5824dffe7eac69cd22581b86f50b0d20330ef10bf567d4adfafe5e06d20f9d7a10c8acfcffb95a3d5c47c50327576d9600761 SHA512 4d3ef5ba2ca54d0f5cd84ece771297c19c05bd276fc235f92c76d469ad17e55b54de696dce38c9039ae9825c7609e03e937536261c4fb680e936865ee0e4441e
|
||||
DIST kitty-0.26.4.tar.xz.sig 566 BLAKE2B 8ac544b077cc30f811be665226e413e3074d3490b99b790c37ff871017131be76163a526f6c5eca6a711724975a4e3d6a6d897f2bacafac6b8f71f8ce141dd8d SHA512 f851daebc0c9d75f39c1e02a3ca14ab77f350c7f606e4e00f4513e084ca86e329dc2da033a6292aaedf683995932e83c58d273552d2afd26a0e541e89bdd4bf9
|
||||
|
||||
131
x11-terms/kitty/kitty-0.26.4.ebuild
Normal file
131
x11-terms/kitty/kitty-0.26.4.ebuild
Normal file
@@ -0,0 +1,131 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
inherit edo optfeature multiprocessing python-single-r1 toolchain-funcs xdg
|
||||
|
||||
if [[ ${PV} == 9999 ]] ; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
|
||||
else
|
||||
inherit verify-sig
|
||||
SRC_URI="
|
||||
https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
|
||||
verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )"
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/kovidgoyal.gpg"
|
||||
KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Fast, feature-rich, GPU-based terminal"
|
||||
HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
IUSE="+X test transfer wayland"
|
||||
REQUIRED_USE="
|
||||
|| ( X wayland )
|
||||
${PYTHON_REQUIRED_USE}"
|
||||
RESTRICT="!X? ( test ) !test? ( test ) !transfer? ( test ) !wayland? ( test )"
|
||||
|
||||
# dlopen: fontconfig,libglvnd
|
||||
RDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
dev-libs/openssl:=
|
||||
media-libs/fontconfig
|
||||
media-libs/harfbuzz:=
|
||||
media-libs/lcms:2
|
||||
media-libs/libglvnd[X?]
|
||||
media-libs/libpng:=
|
||||
sys-apps/dbus
|
||||
sys-libs/zlib:=
|
||||
x11-libs/libxkbcommon[X?]
|
||||
x11-misc/xkeyboard-config
|
||||
~x11-terms/kitty-shell-integration-${PV}
|
||||
~x11-terms/kitty-terminfo-${PV}
|
||||
X? ( x11-libs/libX11 )
|
||||
transfer? ( net-libs/librsync:= )
|
||||
wayland? ( dev-libs/wayland )"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
X? (
|
||||
x11-base/xorg-proto
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXi
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXrandr
|
||||
)
|
||||
wayland? ( dev-libs/wayland-protocols )"
|
||||
BDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
sys-libs/ncurses
|
||||
virtual/pkgconfig
|
||||
test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
|
||||
wayland? ( dev-util/wayland-scanner )"
|
||||
[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# seds unfortunately feel easier on maintainenance than patches here
|
||||
sed -e "s/'x11 wayland'/'$(usev X x11) $(usev wayland)'/" \
|
||||
-e "$(usev !X '/gl_libs =/s/=.*/= []/')" \
|
||||
-e "/num_workers =/s/=.*/= $(makeopts_jobs)/" \
|
||||
-e "s/cflags.append.*-O3.*/pass/" -e 's/-O3//' \
|
||||
-i setup.py || die
|
||||
|
||||
if use !transfer; then
|
||||
sed -i 's/rs_cflag =/& []#/;/files.*rsync/d' setup.py || die
|
||||
rm -r kittens/transfer || die
|
||||
fi
|
||||
|
||||
# test relies on 'who' command which doesn't detect users with pid-sandbox
|
||||
rm kitty_tests/utmp.py || die
|
||||
|
||||
# test may fail/hang depending on environment and shell initialization scripts
|
||||
rm kitty_tests/{shell_integration,ssh}.py || die
|
||||
|
||||
# skip docs for live version
|
||||
[[ ${PV} != 9999 ]] || sed -i '/exists.*_build/,/docs(ddir)/d' setup.py || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
tc-export CC
|
||||
export PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
|
||||
|
||||
local conf=(
|
||||
--disable-link-time-optimization
|
||||
--ignore-compiler-warnings
|
||||
--libdir-name=$(get_libdir)
|
||||
--shell-integration="enabled no-rc"
|
||||
--update-check-interval=0
|
||||
--verbose
|
||||
)
|
||||
|
||||
edo ${EPYTHON} setup.py linux-package "${conf[@]}"
|
||||
use test && edo ${EPYTHON} setup.py build-launcher "${conf[@]}"
|
||||
|
||||
[[ ${PV} == 9999 ]] || mv linux-package/share/doc/{${PN},${PF}} || die
|
||||
rm -r linux-package/share/terminfo || die
|
||||
}
|
||||
|
||||
src_test() {
|
||||
KITTY_CONFIG_DIRECTORY=${T} ./test.py || die # shebang is kitty
|
||||
}
|
||||
|
||||
src_install() {
|
||||
insinto /usr
|
||||
doins -r linux-package/.
|
||||
|
||||
fperms +x /usr/bin/kitty \
|
||||
/usr/$(get_libdir)/kitty/shell-integration/ssh/{askpass.py,kitty}
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "in-terminal image display with kitty icat" media-gfx/imagemagick
|
||||
optfeature "audio-based terminal bell support" media-libs/libcanberra
|
||||
optfeature "opening links from the terminal" x11-misc/xdg-utils
|
||||
}
|
||||
Reference in New Issue
Block a user