dev-libs/libzip: 1.9.0 version bump

See also: https://libzip.org/news/release-1.9.0.html Package-Manager: Portage-3.0.30, Repoman-3.0.3 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-08-06 00:48:18 -07:00 · 2022-06-14 10:04:27 +02:00
parent 851a6bca2b
commit 7ac5d24168
2 changed files with 117 additions and 0 deletions
--- a/dev-libs/libzip/Manifest
+++ b/dev-libs/libzip/Manifest
@@ -1 +1,2 @@
 DIST libzip-1.8.0.tar.xz 760604 BLAKE2B 7aadbd4df909806ff728f9315f91c2f4b4e884464ef36acd668b23739fa57e4f65987b368cae0d728dd6cc1468718e40086cf0dc21f437a5c2cad91b455c0bb1 SHA512 fe94a26a2797dff7c9b27334f29982f8e523dd5095bf32ebcadc6443726864f0ff7b2e8bf243e52cad8f79297bc7a87d73fdbc35edae4ffc8ab6aa0bcc93b03e
+DIST libzip-1.9.0.tar.xz 763704 BLAKE2B 204952e96ddcff0d799cd7f4ce4be868aad6f6555999673eba9bd85382ab26546f6423034fa68461009d095d4a2513b490b2b144aca0caa8c0be0980b35ba124 SHA512 dd0c7046f5b1faf00690774572982e870edaa1819563f9ebf7caf823c9c5718623576a7135a64c9acfed9cefac5601cf944b7aa0b623986f5c85743f3014b349
--- a/dev-libs/libzip/libzip-1.9.0.ebuild
+++ b/dev-libs/libzip/libzip-1.9.0.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake multibuild flag-o-matic
+
+DESCRIPTION="Library for manipulating zip archives"
+HOMEPAGE="https://nih.at/libzip/"
+SRC_URI="https://www.nih.at/libzip/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="bzip2 gnutls lzma mbedtls ssl static-libs test tools zstd"
+REQUIRED_USE="test? ( tools )"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2:= )
+	lzma? ( app-arch/xz-utils )
+	ssl? (
+		gnutls? (
+			dev-libs/nettle:0=
+			>=net-libs/gnutls-3.6.5:=
+		)
+		!gnutls? (
+			mbedtls? ( net-libs/mbedtls:= )
+			!mbedtls? ( dev-libs/openssl:0= )
+		)
+	)
+	zstd? ( app-arch/zstd )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	# Upstream doesn't support building dynamic & static
+	# simultaneously: https://github.com/nih-at/libzip/issues/76
+	MULTIBUILD_VARIANTS=( shared $(usev static-libs) )
+}
+
+src_configure() {
+	append-lfs-flags
+	myconfigure() {
+		local mycmakeargs=(
+			-DBUILD_EXAMPLES=OFF # nothing is installed
+			-DENABLE_COMMONCRYPTO=OFF # not in tree
+			-DENABLE_BZIP2=$(usex bzip2)
+			-DENABLE_LZMA=$(usex lzma)
+			-DENABLE_ZSTD=$(usex zstd)
+		)
+		if [[ ${MULTIBUILD_VARIANT} = static-libs ]]; then
+			mycmakeargs+=(
+				-DBUILD_DOC=OFF
+				-DBUILD_EXAMPLES=OFF
+				-DBUILD_SHARED_LIBS=OFF
+				-DBUILD_TOOLS=OFF
+			)
+		else
+			mycmakeargs+=(
+				-DBUILD_DOC=ON
+				-DBUILD_REGRESS=$(usex test)
+				-DBUILD_TOOLS=$(usex tools)
+			)
+		fi
+
+		if use ssl; then
+			if use gnutls; then
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=$(usex gnutls)
+					-DENABLE_MBEDTLS=OFF
+					-DENABLE_OPENSSL=OFF
+				)
+			elif use mbedtls; then
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=OFF
+					-DENABLE_MBEDTLS=$(usex mbedtls)
+					-DENABLE_OPENSSL=OFF
+				)
+			else
+				mycmakeargs+=(
+					-DENABLE_GNUTLS=OFF
+					-DENABLE_MBEDTLS=OFF
+					-DENABLE_OPENSSL=ON
+				)
+			fi
+		else
+			mycmakeargs+=(
+				-DENABLE_GNUTLS=OFF
+				-DENABLE_MBEDTLS=OFF
+				-DENABLE_OPENSSL=OFF
+			)
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	run_tests() {
+		[[ ${MULTIBUILD_VARIANT} = shared ]] && cmake_src_test
+	}
+
+	multibuild_foreach_variant run_tests
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+}