gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

games-emulation/dosbox: drop 0.74.3, 0.75_pre4302

Browse Source 
Bug: https://bugs.gentoo.org/970396
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2026-02-22 08:46:56 +01:00
parent 012530dd77
commit 7aacd51b77
3 changed files with 0 additions and 170 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
games-emulation/dosbox/Manifest
View File

@@ -1,3 +1,2 @@
DIST dosbox-0.74-3.tar.gz 1326339 BLAKE2B bc25e6aba29747d4060269809d729904d8d187527c59953125c8591c0a91cf4583223c1bcf1224a041d44bfe5efcfe9034d6572954cf26870a290ff1b27e7d9d SHA512 3770f1578e71730168fba01809585f2a05cf8c4d420524687ba28791d242faad294401bb9cd268bba725798e1db853551f274dc00a4024331f5dcef9f87f8f5f
DIST dosbox-code-0-r4302-dosbox-trunk.zip 1443140 BLAKE2B 91e7c5ceb90baa09fd30cf0d8799d900d6bcd94f2b1eead8493ee276b1ee038e093fde56874c58d379218b60e1b510f1d493d72fc275f206912304312ce58d0b SHA512 57758950fd3f0440f4e4d59191a059387a0c7c4559376a2ba826537423ac63d266defe2da37be81450bfece3e0d1caa79b7097ea7fcd3cf96cd04d8899123c69
DIST dosbox_glide-841e1071597b64ead14dd08c25a03206b2d1d1b6.diff 96801 BLAKE2B d24d1f4262129899d807c275b1ae2d6c09056a126441665f37359302428f30576f399c4778b55f4eaec674e714d85243f576bfa3064887c5801daddc9e507aad SHA512 4cbe0ede9c4242aa346ca6c609b7a4d8e4e1d204d79d93ff741d58d3ca14e43a2e49cd696bd4bd54c13e62d1080320ee233963bac26f25bb0b4fada86e813ca2

71
games-emulation/dosbox/dosbox-0.74.3.ebuild
View File

@@ -1,71 +0,0 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools desktop
case ${PV} in
9999)
MY_P=${PN}
ESVN_REPO_URI="https://svn.code.sf.net/p/dosbox/code-0/dosbox/trunk"
inherit subversion
;;
*_pre*)
MY_PV=0-r${PV#*_pre}
MY_P=${PN}-code-${MY_PV}-${PN}-trunk
SRC_URI="https://sourceforge.net/code-snapshots/svn/d/do/dosbox/code-0/${MY_P}.zip"
BDEPEND="app-arch/unzip"
;;
*)
MY_PV=$(ver_rs 2 -)
MY_P=${PN}-${MY_PV}
SRC_URI="https://downloads.sourceforge.net/dosbox/${MY_P}.tar.gz"
;;
esac
DESCRIPTION="DOS emulator"
HOMEPAGE="https://www.dosbox.com/"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ~ppc ppc64 x86"
IUSE="alsa +core-inline debug hardened opengl X"
RDEPEND="alsa? ( media-libs/alsa-lib )
opengl? ( virtual/glu virtual/opengl )
debug? ( sys-libs/ncurses:0= )
X? ( x11-libs/libX11 )
media-libs/libpng:0=
media-libs/libsdl[joystick,opengl?,video,X?]
media-libs/sdl-net
media-libs/sdl-sound
virtual/zlib:="
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-0.74-ncurses.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
ac_cv_lib_X11_main=$(usex X yes no) \
econf \
$(use_enable alsa alsa-midi) \
$(use_enable core-inline) \
$(use_enable !hardened dynamic-core) \
$(use_enable !hardened dynamic-x86) \
$(use_enable debug) \
$(use_enable opengl)
}
src_install() {
default
make_desktop_entry dosbox DOSBox /usr/share/pixmaps/dosbox.ico
doicon src/dosbox.ico
}

98
games-emulation/dosbox/dosbox-0.75_pre4302.ebuild
View File

@@ -1,98 +0,0 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools desktop flag-o-matic
case ${PV} in
9999)
MY_P=${PN}
ESVN_REPO_URI="https://svn.code.sf.net/p/dosbox/code-0/dosbox/trunk"
inherit subversion
;;
*_pre*)
MY_PV=0-r${PV#*_pre}
MY_P=${PN}-code-${MY_PV}-${PN}-trunk
SRC_URI="https://sourceforge.net/code-snapshots/svn/d/do/dosbox/code-0/${MY_P}.zip"
BDEPEND="app-arch/unzip"
;;
*)
MY_PV=$(ver_rs 2 -)
MY_P=${PN}-${MY_PV}
SRC_URI="https://downloads.sourceforge.net/dosbox/${MY_P}.tar.gz"
;;
esac
GLIDE_PATCH=841e1071597b64ead14dd08c25a03206b2d1d1b6
SRC_URI+=" glide? ( https://raw.githubusercontent.com/voyageur/openglide/${GLIDE_PATCH}/platform/dosbox/dosbox_glide.diff -> dosbox_glide-${GLIDE_PATCH}.diff )"
DESCRIPTION="DOS emulator"
HOMEPAGE="https://www.dosbox.com/"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ~ppc ppc64 x86"
IUSE="alsa +core-inline debug glide hardened opengl X"
RDEPEND="alsa? ( media-libs/alsa-lib )
glide? ( media-libs/openglide )
opengl? ( virtual/glu virtual/opengl )
debug? ( sys-libs/ncurses:0= )
X? ( x11-libs/libX11 )
media-libs/libpng:0=
media-libs/libsdl[joystick,opengl?,video,X?]
media-libs/sdl-net
media-libs/sdl-sound
virtual/zlib:="
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-0.74-ncurses.patch
"${FILESDIR}"/${PN}-0.75-detect-AR.patch
)
src_prepare() {
use glide && eapply "${DISTDIR}"/dosbox_glide-${GLIDE_PATCH}.diff "${FILESDIR}"/${PN}-0.75-glide-libdl.patch
default
eautoreconf
}
src_configure() {
# -Werror=strict-aliasing, -Weror=odr
# https://bugs.gentoo.org/858638
#
# Upstream is kinda dead. Just use dosbox-staging... where I reported
# similar issues and they were fixed. ;)
append-flags -fno-strict-aliasing
filter-lto
use glide && append-cppflags -I"${EPREFIX}"/usr/include/openglide
ac_cv_lib_X11_main=$(usex X yes no) \
econf \
$(use_enable alsa alsa-midi) \
$(use_enable core-inline) \
$(use_enable !hardened dynamic-core) \
$(use_enable !hardened dynamic-x86) \
$(use_enable debug) \
$(use_enable opengl)
}
src_install() {
default
make_desktop_entry dosbox DOSBox /usr/share/pixmaps/dosbox.ico
doicon src/dosbox.ico
}
pkg_postinst() {
if use glide; then
elog "You have enabled unofficial Glide emulation. To use this, symlink"
elog "or copy ${EPREFIX}/usr/share/openglide/glide2x-dosbox.ovl to your game's"
elog "directory and add the following to your DOSBox configuration."
elog ""
elog "[glide]"
elog "glide=true"
fi
}