app-doc/gnucash-docs: Bump to 4.5

Bug: https://bugs.gentoo.org/780501
Signed-off-by: Aaron W. Swenson <titanofold@gentoo.org>

app-doc/gnucash-docs/Manifest

@@ -1 +1,2 @@
 DIST gnucash-docs-4.4.tar.gz 62534210 BLAKE2B 0c3cdc3ccdf1cfb7a54e44dcde9ea10672cb312e6d6e083ae9bb65bc52b044e8559647a8491f6fa762d9bb84c33f22dd9cacb3a862548994bdc7c56b3e634aa9 SHA512 60e34af3fdb144fefc835d6497fd442daad1417c4e40f8b4fd8f66a37cd0cfa1d789aa03de435d4654ee2368a4b85e9b0cfba8eeef61829e0ca190a453a9abdc
+DIST gnucash-docs-4.5.tar.gz 71420078 BLAKE2B cf4cf6f62e0ce1c5f868f91b6452a531e14a4fb85c801a941e5b19a9a3e61593a248cc79c753e23d9fb40809f27194117d6e73c7723f9454c2c2d0658fcd77e0 SHA512 27fcb649ad813d2aa148b8a910a6d35fcb47e79b0c36e6b2456d733f8f969686234e090d128ccb4a2227c71385dfa9d9236606a3e9354923e128644ee0be137f

app-doc/gnucash-docs/gnucash-docs-4.5.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools optfeature
+
+DESCRIPTION="Documentation package for GnuCash"
+HOMEPAGE="https://www.gnucash.org/"
+SRC_URI="https://github.com/Gnucash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2 FDL-1.1"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+LOCALES=( de it ja pt )
+IUSE="${LOCALES[*]/#/l10n_}"
+
+DEPEND="
+	app-text/docbook-xml-dtd:4.5
+	app-text/docbook-xsl-stylesheets
+	app-text/rarian
+	dev-libs/libxml2
+	dev-libs/libxslt
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_compile() {
+	:
+}
+
+src_install() {
+	local doc_type my_lang
+
+	for doc_type in help guide; do
+		for my_lang in C ${L10N}; do
+			case $my_lang in
+				# Both help and guides translated
+				C|de|it|pt) ;;
+				ja) # Only guides translated
+					if [[ ${doc_type} = "help" ]] ; then
+						elog "Help documentation hasn't been translated for $my_lang"
+						elog "Will do English instead."
+						continue
+					fi
+					;;
+				*)
+					die "Invalid locale: $my_lang"
+					;;
+			esac
+
+			emake -C "${doc_type}/${my_lang}" DESTDIR="${D}" install
+		done
+	done
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	optfeature "generating PDF files" dev-java/fop
+	optfeature "viewing the docs" gnome-extra/yelp
+}