net-p2p/ktorrent: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2023-04-22 11:12:16 +02:00
parent 85bbd33ce3
commit 7a4938bdfd
2 changed files with 95 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST ktorrent-22.12.3.tar.xz 2144172 BLAKE2B 627dd303153aa0189d44bb944e6dba4ac91e2bbf9919780de671c8ce88984c9743ea76b415b2d5140e1f69a68dc94405ff7f256fe0bc4f3d6118d7e453b4ced7 SHA512 7e7c11a80758b399fc1a66e505e087ab846b837e5e8fec0f310156605423d078b92e0c3a75669c3f85fb3119781ce9350ef0e29ccb5b8fb2685c7aab127b85d9
DIST ktorrent-23.04.0.tar.xz 2150160 BLAKE2B 896fc4c7d0bf84128dd28a00dc824848e06c2919766c63cb35eb635753236890bae4d7af281a2fd5ab51c4ab19648695003991dc29592d38c740c4092c3da1df SHA512 f761d3de70397c588da05069062c2dab7286267726cc134780740d087dfe890b76c78aa94e296b6b66a4299eb2a27400b4689df5a6d60108781c317c42e123a5
+94
View File
@@ -0,0 +1,94 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="optional"
KFMIN=5.104.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.5
VIRTUALX_REQUIRED="test"
inherit ecm gear.kde.org
DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
HOMEPAGE="https://apps.kde.org/ktorrent/"
LICENSE="GPL-2"
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
+mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
COMMON_DEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=net-libs/libktorrent-${PVCUT}:5
infowidget? ( dev-libs/geoip )
mediaplayer? (
>=media-libs/phonon-4.11.0
>=media-libs/taglib-1.5
)
rss? (
>=dev-qt/qtwebengine-${QTMIN}:5
>=kde-frameworks/syndication-${KFMIN}:5
)
shutdown? ( kde-plasma/libkworkspace:5 )
stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/boost-1.71
"
RDEPEND="${COMMON_DEPEND}
ipfilter? (
app-arch/bzip2
app-arch/unzip
kde-apps/kio-extras:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
)
"
BDEPEND="sys-devel/gettext"
src_configure() {
local mycmakeargs=(
-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
$(cmake_use_find_package rss KF5Syndication)
-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
-DENABLE_STATS_PLUGIN=$(usex stats)
-DENABLE_UPNP_PLUGIN=$(usex upnp)
-DENABLE_SEARCH_PLUGIN=$(usex webengine)
-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
)
# add back when ported
# -DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
ecm_src_configure
}