app-backup/dar: bump version to 2.6.13-r1

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Co-authored-by: Doug Freed <dwfreed@mtu.edu>
Co-authored-by: Sam James <sam@gentoo.org>
Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
This commit is contained in:
Viorel Munteanu
2021-03-12 13:29:05 +02:00
committed by Joonas Niilola
co-authored by Doug Freed Sam James
parent 8db7131e01
commit 79efa739e7
2 changed files with 112 additions and 2 deletions
+102
View File
@@ -0,0 +1,102 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic
DESCRIPTION="A full featured backup tool, aimed for disks"
HOMEPAGE="http://dar.linux.free.fr/"
SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
IUSE="curl dar32 dar64 doc gcrypt gpg lzo nls static static-libs xattr"
RESTRICT="test" # need to be run as root
RDEPEND="
>=sys-libs/zlib-1.2.3:=
!static? (
app-arch/bzip2:=
app-arch/xz-utils:=
sys-libs/libcap
curl? ( net-misc/curl )
gcrypt? ( dev-libs/libgcrypt:0= )
gpg? ( app-crypt/gpgme )
lzo? ( dev-libs/lzo:= )
xattr? ( sys-apps/attr:= )
)"
DEPEND="
${RDEPEND}
static? (
app-arch/bzip2[static-libs]
app-arch/xz-utils[static-libs]
sys-libs/libcap[static-libs]
sys-libs/zlib[static-libs]
curl? ( net-misc/curl[static-libs] )
lzo? ( dev-libs/lzo[static-libs] )
xattr? ( sys-apps/attr[static-libs] )
)
"
BDEPEND="
nls? (
sys-devel/gettext
virtual/libintl
)
doc? ( app-doc/doxygen )
"
REQUIRED_USE="?? ( dar32 dar64 )
gpg? ( gcrypt )"
src_configure() {
# configure.ac is totally funked up regarding the AC_ARG_ENABLE
# logic.
# For example "--enable-dar-static" causes configure to DISABLE
# static builds of dar.
# Do _not_ use $(use_enable) until you have verified that the
# logic has been fixed by upstream.
local myconf=(
--disable-python-binding
--disable-upx
$(usex curl '' --disable-libcurl-linking)
$(usex dar32 --enable-mode=32 '')
$(usex dar64 --enable-mode=64 '')
$(usex doc '' --disable-build-html)
#$(usex examples --enable-examples '')
$(usex gcrypt '' --disable-libgcrypt-linking)
$(usex gpg '' --disable-gpgme-linking)
$(usex lzo '' --disable-liblzo2-linking)
$(usex nls '' --disable-nls)
#$(usex rsync '' --disable-librsync-linking)
$(usex xattr '' --disable-ea-support)
)
# Bug 103741
filter-flags -fomit-frame-pointer
if ! use static ; then
myconf+=( --disable-dar-static )
if ! use static-libs ; then
myconf+=( --disable-static )
fi
fi
econf "${myconf[@]}"
}
src_install() {
emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
local DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
einstalldocs
find "${ED}" -name '*.la' -delete || die
if ! use static-libs ; then
find "${ED}" -name '*.a' -delete || die
fi
}
+10 -2
View File
@@ -1,7 +1,14 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<!-- maintainer-needed -->
<maintainer type="person">
<email>ceamac.paragon@gmail.com</email>
<name>Viorel Munteanu</name>
</maintainer>
<maintainer type="project">
<email>proxy-maint@gentoo.org</email>
<name>Proxy Maintainers</name>
</maintainer>
<longdescription>
Backup directory tree and files.
Full featured archiver with support for differential backups, slices,
@@ -14,7 +21,8 @@ operations, including with ssh.
<flag name="dar64">Enables --enable-mode=64 option, which replace infinite
by 64 bit integers</flag>
<flag name="gcrypt">Enables strong encryption support</flag>
<flag name="gpg">Enables usage of asymetric crypto algorithms</flag>
<flag name="gpg">Enables usage of asymmetric encryption algorithms</flag>
<flag name="rsync">Enables linking with <pkg>net-libs/librsync</pkg> for delta compression support</flag>
</use>
<upstream>
<remote-id type="sourceforge">dar</remote-id>