games-engines/frotz: update to 2.52

New version can be compiled with GCC 10 (#707608).

Closes: https://bugs.gentoo.org/707608
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Signed-off-by: Stefan Strogin <steils@gentoo.org>

games-engines/frotz/Manifest

@@ -1 +1,2 @@
 DIST frotz-2.50b2.tar.bz2 281065 BLAKE2B bffe35e9f77e7ef89b76bbe29a3f97ad94ac529bd4930790a25c147f336036b1bfdae1ea52cf87e62121189f4e1bce890f5bc3ddbfb0e68e9ffa290fc1567cc9 SHA512 12398c5bf963aaa7e1ad51a1ca3afaddf4849c2aed8e2cabffc411294b501181de69f99bad2a1c8de9777df4b448af6d85b695c56de4b3112cd32fd7d6cb33c7
+DIST frotz-2.52.tar.bz2 289109 BLAKE2B d1e97e05d1da187846c64dacdf69f34a800be97b75121dc8de63c619687ed5ccbd6b03b2391d2896a14aaad1e4f8eb51926affb92a36f1a5bad8acec91524774 SHA512 387e7a7fe0cffd40b639a306eef89a22421a4ff4a8e5dbcf96a1ef3b901744b3f75a671953ecdc17bde0d699e4756d470b61c8213c47315baa2700da92d06710

games-engines/frotz/frotz-2.52.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Interpreter for Z-code based text games"
+HOMEPAGE="https://661.org/proj/if/frotz/"
+SRC_URI="https://gitlab.com/DavidGriffith/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="ncurses sdl sound unicode"
+REQUIRED_USE="sound? ( || ( ncurses sdl ) )"
+
+DEPEND="
+	ncurses? (
+		sys-libs/ncurses:0=[unicode?]
+		sound? (
+			media-libs/libao
+			media-libs/libmodplug
+			media-libs/libsamplerate
+			media-libs/libsndfile[-minimal]
+			media-libs/libvorbis
+		)
+	)
+	sdl? (
+		media-libs/freetype:2
+		media-libs/libpng:0=
+		media-libs/libsdl2[sound,threads,video]
+		media-libs/sdl2-mixer[mod,vorbis,wav]
+		sys-libs/zlib
+		virtual/jpeg:0=
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_compile() {
+	emake \
+		dumb \
+		$(use ncurses && echo ncurses) \
+		$(use sdl && echo sdl) \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		RANLIB="$(tc-getRANLIB)" \
+		CURSES=$(usex unicode ncursesw ncurses) \
+		USE_UTF8=$(usex unicode yes "") \
+		SOUND_TYPE=$(usex sound ao none) \
+		PREFIX="${EPREFIX}/usr" \
+		SYSCONFDIR="${EPREFIX}/etc"
+}
+
+src_install() {
+	emake \
+		install_dumb \
+		$(use ncurses && echo install) \
+		$(use sdl && echo install_sdl) \
+		PREFIX="${EPREFIX}/usr" \
+		DESTDIR="${D}"
+
+	dodoc \
+		AUTHORS ChangeLog CONTRIBUTORS DUMB HOW_TO_PLAY README TODO \
+		doc/frotz.conf-{big,small}
+}
+
+pkg_postinst() {
+	echo
+	elog "Global config file can be installed in ${EPREFIX}/etc/frotz.conf"
+	elog "Sample config files are in ${EPREFIX}/usr/share/doc/${PF}"
+	echo
+}