app-crypt/eid-mw: remove old 5.0.8

Package-Manager: Portage-3.0.9, Repoman-2.3.23
Signed-off-by: Amy Liffey <amynka@gentoo.org>

app-crypt/eid-mw/Manifest

@@ -1,3 +1,2 @@
 DIST eid-mw-4.4.27.tar.gz 7481892 BLAKE2B 5d1268946a62436eec74a7ed83e8391c1ceb0274ef8798b95bee2087e4e439d46ea5f88b8237cff1e925d31d1762fe979a959ce35efd4d6210dda580827bab3b SHA512 c4e9917907bb351b9dd427eb48c2124e55de0d8a73cfd142b9cb5e81c84f91e62a39a90bb1fbd109fb59aeb089898ffcd18ef5ccf2ab72c883b41ec4d9b9edf1
 DIST eid-mw-5.0.11.tar.gz 8928406 BLAKE2B 36358b758e1e865a7a99099f548b8e7acc045df73ab6290dc5ebf7e82c8b03566137340498e815cdb3458c63961233ef0e8530f75dfeed18e714b6fb4fcfbbcd SHA512 2753739797dbfe5b01c4538fca02f5a0833a3850a2b62cd4e7179a148b0459c9217311f44d1f03b9b9655187af7d90cbe53dd1e4a8318a0cba864d346f8c9324
-DIST eid-mw-5.0.8.tar.gz 8782476 BLAKE2B ece43bff5de108f4d92534aeda3d88c1109fbf54f99c4de0442c02958a9b0edef3e34d94015b9f3a865317d88c2bd21d1adbbf15010cd1fbd99787985190dee5 SHA512 dc9eaaec419082bc6e1f6cd11063c79c5aac0e7910027d9cbb34dbe8ede9d600c93b7b38a7e4491c5eb9a0068e537d78854b3fc3b2581d464dd4939185469e46

app-crypt/eid-mw/eid-mw-5.0.8.ebuild

@@ -1,108 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools desktop gnome2-utils xdg-utils
-
-DESCRIPTION="Electronic Identity Card middleware supplied by the Belgian Federal Government"
-HOMEPAGE="https://eid.belgium.be"
-SRC_URI="https://codeload.github.com/fedict/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
-IUSE="+dialogs +gtk +p11v220 p11-kit"
-
-RDEPEND=">=sys-apps/pcsc-lite-1.2.9
-	gtk? (
-		x11-libs/gdk-pixbuf[jpeg]
-		x11-libs/gtk+:3
-		dev-libs/libxml2
-		net-misc/curl[ssl]
-		net-libs/libproxy
-		app-crypt/pinentry[gtk]
-	)
-	p11-kit? ( app-crypt/p11-kit )"
-
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-REQUIRED_USE="dialogs? ( gtk )"
-
-src_prepare() {
-	default
-
-	# Buggy internal versioning when autoreconf a tarball release.
-	# Weird numbering is required otherwise we get a seg fault in
-	# about-eid-mw program.
-	echo "${PV}-v${PV}" > .version
-
-	# xpi module : we don't want it anymore
-	sed -i -e '/SUBDIRS/ s:plugins_tools/xpi ::' Makefile.am || die
-	sed -i -e '/plugins_tools\/xpi/ d' configure.ac || die
-
-	# hardcoded lsb_info
-	sed -i \
-		-e "s:get_lsb_info('i'):strdup(_(\"Gentoo\")):" \
-		-e "s:get_lsb_info('r'):strdup(_(\"n/a\")):" \
-		-e "s:get_lsb_info('c'):strdup(_(\"n/a\")):" \
-		plugins_tools/aboutmw/gtk/about-main.c || die
-
-	# Fix libdir for pkcs11_manifestdir
-	sed -i \
-		-e "/pkcs11_manifestdir/ s:prefix)/lib:libdir):" \
-		cardcomm/pkcs11/src/Makefile.am || die
-
-	# See bug #732994
-	sed -i \
-		-e '/LDFLAGS="/ s:$CPPFLAGS:$LDFLAGS:' \
-		configure.ac || die
-
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		$(use_enable dialogs) \
-		$(use_enable p11v220) \
-		$(use_enable p11-kit p11kit) \
-		$(use_with gtk gtkvers 'detect') \
-		--with-gnu-ld \
-		--disable-static
-}
-
-src_install() {
-	default
-	rm -r "${ED}"/usr/$(get_libdir)/*.la || die
-	if use gtk; then
-		domenu plugins_tools/eid-viewer/eid-viewer.desktop
-		doicon plugins_tools/eid-viewer/gtk/eid-viewer.png
-	fi
-}
-
-pkg_postinst() {
-	if use gtk; then
-		gnome2_schemas_update
-		xdg_desktop_database_update
-		xdg_icon_cache_update
-
-		local peimpl=$(eselect --brief --colour=no pinentry show)
-		case "${peimpl}" in
-		*gtk*) ;;
-		*)	ewarn "The pinentry front-end currently selected is not supported by eid-mw."
-			ewarn "You may be prompted for your pin code in an inaccessible shell!!"
-			ewarn "Please select pinentry-gtk-2 as default pinentry provider:"
-			ewarn " # eselect pinentry set pinentry-gtk-2"
-		;;
-		esac
-	fi
-}
-
-pkg_postrm() {
-	if use gtk; then
-		gnome2_schemas_update
-		xdg_desktop_database_update
-		xdg_icon_cache_update
-	fi
-}