dev-python/weasyprint: Bump to 52.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/weasyprint/Manifest

@@ -1,2 +1,3 @@
 DIST WeasyPrint-51.tar.gz 308411 BLAKE2B f88f9e1abc09986d51d92d8a153c71242cadc8ce6b8ac99a08d86746677d40a86affe3c56dd3e3e6a0eb2fc915f77036271f049f6ccc644d508be51d01d97b7c SHA512 631038bece7ac0c15c6a668a7d06137e4bccc049eb80484a153ca9c4a996256de8647428b21ed1d0c1607af3893c747a1956a3d3f012b30105ba4f8613a96fcd
 DIST WeasyPrint-52.3.tar.gz 325076 BLAKE2B 2981a487938d4ceefe20da36262438a64c30beaff340be6bd48b0140f63ea3971ca80a36386dde2db270e1555b137a89480673c4fdc2fa49079efdf58e53029b SHA512 7db740dd8f7264f73efe6e2505c603cedb1f8e5c053447b03517bdb003b933e1ef58f15482d4ab316b04b6631f9102752670f8b56989983cab80f7bd110746c9
+DIST WeasyPrint-52.4.tar.gz 325062 BLAKE2B ead641007e84664dfc1a9b95a227d5c6539e19e629d95d68b663b46a873ffa83b203897dd4d03c5d72f00e2737268c64624b97a37840c86d4a555f5b1a20a7bb SHA512 0003f9b46452e60118e7f6944f0bf48b6f548814dae10f990bedb124d3c67d9c530c30ee142d416f448b3b479f54b4fcdf01e31747957438192c77031926cb8c

dev-python/weasyprint/weasyprint-52.4.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+MY_PN="WeasyPrint"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Visual rendering engine for HTML and CSS that can export to PDF"
+HOMEPAGE="https://weasyprint.org https://github.com/Kozea/WeasyPrint"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="jpeg tiff"
+
+# Note: specific subslot of pango since it inlines some of pango headers.
+#	>=dev-python/lxml-3.0[${PYTHON_USEDEP}]
+RDEPEND="
+	>=dev-python/cairocffi-0.9[${PYTHON_USEDEP}]
+	>=dev-python/cffi-0.6:=[${PYTHON_USEDEP}]
+	>=dev-python/cssselect2-0.1[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-0.999999999[${PYTHON_USEDEP}]
+	>=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tinycss2-1.0.0[${PYTHON_USEDEP}]
+	>=media-gfx/cairosvg-2.4.0[${PYTHON_USEDEP}]
+	>=x11-libs/cairo-1.15.4
+	x11-libs/gdk-pixbuf[jpeg?,tiff?]
+	x11-libs/pango:0/0
+"
+
+BDEPEND="
+	test? (
+		media-fonts/ahem
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/pytest-runner/d' \
+		-e 's:--flake8 --isort::' \
+		-i setup.cfg || die
+	distutils-r1_src_prepare
+}