kde-apps/umbrello: 26.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/umbrello/Manifest

@@ -1,2 +1,3 @@
 DIST umbrello-26.04.3.tar.xz 5654672 BLAKE2B 96991f92c23cf9d958a3ac609b93e3be2ef6aac70c69f5ce8bcdb8f888f02ff31a0f180e71b90d03fa3e36b7800d0248e4dcc6d490a72a543d776f108e63668d SHA512 3f3e1ec4a975d4203149a43a69ca085ae2bedab7039ce0d268609c86f0fc5c2b955c863ac7305067e81bc939a889714596121facfc780e8c8531c6f11504f7b1
 DIST umbrello-26.08.0.tar.xz 5658076 BLAKE2B e6cbffd522c5309170c00b3a564ed2c2331792e0744dc278d60a260cd05e88119784d0c90bc8993b429648809d3531c7fcfcf1ef53545a312d88e6c1491f25d3 SHA512 e46fcdc0c0f22f69b5a9b3a9829419cc468f932a69a88fe467f72aba20039245c7c7c1fe37ae61a9186a3a1f24bcd25f9a6927f7df19c1809083ea0f0e45c677
+DIST umbrello-26.08.1.tar.xz 5661540 BLAKE2B e20abeec544894ca6c33956107b9866af61189a9001050af8b49d49f25141324cdb9ad60bcdcc738e96ab4e6e9f961e38b887cc39de3974963813012457513b7 SHA512 58f33f97f2c068d92f8a0bb56cb0257592105277deb75f98c7f60c3645961da8427dcaa02af5b741a07f9f8e97ebf4f6f358b3d788c5f19b3978886dd13db1db

kde-apps/umbrello/umbrello-26.08.1.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=6.27.0
+QTMIN=6.11.2
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2:=
+	dev-libs/libxslt
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,xml]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	php? (
+		dev-util/kdevelop:6=
+		dev-util/kdevelop-pg-qt:0
+		dev-util/kdevelop-php:6
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-24.11.80-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DBUILD_APIDOC=OFF
+		-DBUILD_PHP_IMPORT=$(usex php)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}