mate-extra/caja-extensions: add 1.26.0

Bug: https://bugs.gentoo.org/809062
Signed-off-by: Oz N Tiram <oz.tiram@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

mate-extra/caja-extensions/Manifest

@@ -1 +1,2 @@
 DIST caja-extensions-1.24.1.tar.xz 552340 BLAKE2B fff9b70ccdc79905283bdd4e773c8ad6e85cbbc543f4f70af992d91eba1e86d8c2be074dab4154360b836179718e8dbb2837261779a20321b42a2d00c69088ec SHA512 b844a774271d81ac811b1aff1f04be4a65c6e38a683938dfb593f65297a6398fbfe4c8f6a51c649a1311fb5ca8134b4478860f51b1b3eaf9965a6b8776af2817
+DIST caja-extensions-1.26.0.tar.xz 571084 BLAKE2B 85e88e6f4d9de37109dc099c92c24c0cbe231def82e637a68005ae8c1b0658467638be8b4d2ba7a0f7f1e9f1d3c93d9f5114899b2ca2c65531086716cd96ea8e SHA512 c60ac189328853ed309b60cdabce302feb79de62b2fb19156b55055d26ff29e6be05badc3e7eba2fba3de9870b04851bacfb0e92dc47b6fb656273caa980ddc7

mate-extra/caja-extensions/caja-extensions-1.26.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+DESCRIPTION="Several Caja extensions"
+LICENSE="GPL-2+"
+SLOT="0"
+
+SENDTO="cdr gajim +mail pidgin upnp"
+IUSE="image-converter nls +open-terminal share +wallpaper xattr ${SENDTO}"
+
+COMMON_DEPEND=">=dev-libs/glib-2.50:2
+	>=mate-base/caja-1.21.3
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3
+	gajim? (
+		>=dev-libs/dbus-glib-0.60
+		>=sys-apps/dbus-1
+	)
+	open-terminal? ( >=mate-base/mate-desktop-1.17.0 )
+	pidgin? ( >=dev-libs/dbus-glib-0.60 )
+	upnp? ( >=net-libs/gupnp-0.13:0= )
+	xattr? ( sys-apps/attr )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	mate-base/mate-desktop
+	cdr? ( >=app-cdr/brasero-2.32.1:= )
+	gajim? ( net-im/gajim )
+	image-converter? (
+		|| (
+			media-gfx/imagemagick
+			media-gfx/graphicsmagick[imagemagick]
+		)
+	)
+	pidgin? ( net-im/pidgin )
+"
+
+BDEPEND="${COMMON_DEPEND}
+	dev-libs/libxml2
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local sendto_plugins="removable-devices"
+	use cdr && sendto_plugins+=",caja-burn"
+	use mail && sendto_plugins+=",emailclient"
+	use pidgin && sendto_plugins+=",pidgin"
+	use gajim && sendto_plugins+=",gajim"
+	use upnp && sendto_plugins+=",upnp"
+
+	mate_src_configure \
+		--enable-sendto \
+		--with-sendto-plugins=${sendto_plugins}\
+		--disable-gksu \
+		$(use_enable image-converter) \
+		$(use_enable nls) \
+		$(use_enable open-terminal) \
+		$(use_enable share) \
+		$(use_enable wallpaper) \
+		$(use_enable xattr xattr-tags)
+}