x11-misc/picom: add 12.2

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

x11-misc/picom/Manifest

@@ -1,2 +1,3 @@
 DIST picom-11.2.tar.gz 308679 BLAKE2B d592dce3e67bc3df68cbece00cd4446ea6214b994d9ceffdd3d43a983e4a520f7a92c9c09bec12f49f18b4e581a4122c363f8de0c156bfe2e99fa09b04ec2196 SHA512 df8fc1a593e108b37be185129ac1f3a23c2ae648a04352c45b9d5888838e5754c68f2eb684f12f1ed4d973eca0aef83a61789f028c63bc2d0f0f38902232aadc
 DIST picom-12.1.tar.gz 672958 BLAKE2B c95fa99f0e121db75cfd8ac23a7f0732603bf236a3e3e0af9089569a1144ebc8499c1dbf5a651d99cd95ec111e6c0091f24e85f6cfccba031e9d85854d8ee160 SHA512 31440a56cdc811e544ab0ed58f0fbbd888cda4ebce569d2ba8ea717b565379355763f82df429e1921d928bfeb96e1c3fe35a0e16b3d463524cd704ccff00a6d5
+DIST picom-12.2.tar.gz 673913 BLAKE2B 10b73334577481adbda571af8973dc3c166e33fa6dca3aec51263f9223b5ff28438b00090755a28f411a5df7b238c68bfadcf5c97a6f638a73d020ffa21dbcd0 SHA512 63129b5051253876aae8dd82cef78e3345b4f96554753bd1ecd7d9c31af369dc52c08226949545e39e14d35e4af4afad17a06cedc6aedff4ba52c53506605884

x11-misc/picom/picom-12.2.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+inherit meson python-any-r1 virtualx xdg
+
+DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
+HOMEPAGE="https://github.com/yshui/picom"
+SRC_URI="https://github.com/yshui/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dbus +doc +drm opengl pcre test"
+
+REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
+RESTRICT="test" # but tests require dbus_next
+
+RDEPEND="dev-libs/libconfig:=
+	dev-libs/libev
+	dev-libs/uthash
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/pixman
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-renderutil
+	dbus? ( sys-apps/dbus )
+	drm? ( x11-libs/libdrm )
+	opengl? (
+		media-libs/libepoxy
+		virtual/opengl
+	)
+	pcre? ( dev-libs/libpcre2:= )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig
+	doc? ( dev-ruby/asciidoctor )
+	test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
+"
+
+DOCS=( README.md picom.sample.conf )
+
+python_check_deps() {
+	python_has_version "dev-python/xcffib[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use dbus)
+		$(meson_use doc with_docs)
+		$(meson_use opengl)
+		$(meson_use pcre regex)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
+}