dev-python/osc-lib: add 4.3.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/osc-lib/Manifest

@@ -1 +1,2 @@
 DIST osc_lib-4.2.0.tar.gz 101802 BLAKE2B a3bb7998e8f54786606bcac528c1562c0d405d14eb5079b46ee5cb849c9284e183d3b4baee2a3ea803ac8e9c45262f3e058eace6b262c13088463a8e79a49154 SHA512 27b393187b97764ec10b0693713724377bfe636613bb84c6edac6aa52668fcdcbaa067e7dfdfd5c6b443a00adbec4dd9fc1542a9f1a9c36652b7dab874fc9e10
+DIST osc_lib-4.3.0.tar.gz 104796 BLAKE2B 412a01ca32a4929bec3b7253f64123d50adca81d515df9b3e0bfeba9a9c0627ee2d0091919cd6ad2b25bc277e740d361bc46c8d9b981dfba703b91b1266781e0 SHA512 ce0185629ee71df090efd98c6f702b3977d89e5c1a1f2dda78a4df0ef63ee184fc3a67ddf26b67f2d3314066b376e6b976e5a14a654f287edfdfd38dad77b478

dev-python/osc-lib/osc-lib-4.3.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A package of common support modules for writing OSC plugins"
+HOMEPAGE="
+	https://opendev.org/openstack/osc-lib/
+	https://github.com/openstack/osc-lib/
+	https://pypi.org/project/osc-lib/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cliff-4.9.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-5.10.0[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# need to skip all tests under TestTagHelps class
+	# checks exact help message, based on another unittest runner
+	sed -e '179,$s/test_add_tag_/_&/' -i osc_lib/tests/utils/test_tags.py || die
+	distutils-r1_src_prepare
+}