xfce-base/libxfce4ui: Bump to 4.17.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4ui/Manifest

@@ -1,2 +1,3 @@
 DIST libxfce4ui-4.16.1.tar.bz2 785811 BLAKE2B d1267b328b7e2d07bfe85ce320da6a60d5a7d739c5ded9b213b83b0cde2061d3badc937e71c4353291ed435fb9d1294cadcc99402cdae69f4bcecf412dd525f2 SHA512 c183bbc75539c777fe704d0a1c4e533fdd2efb6cbc980cfedc2eaa80d0e6223db038498774ffcdc720d7f991dd8d9634183a757a4c4d1728cc9956a33cb187d0
 DIST libxfce4ui-4.17.6.tar.bz2 894189 BLAKE2B 6fa80d3252c300af5f6a84a991481d3fe9595702e787f44510799201a911384252081ba0c579cde54baec426259c8caaa9d05a55b81e2072c9d4da80ed795f5f SHA512 317fd101ea594c10b24b1fb14f217bc454d86bba9c11cdea07898505bee84af40dac7e81bbd3ecbdd8894ead662d5041d2e90248151f317150c9b2de8beb84b9
+DIST libxfce4ui-4.17.7.tar.bz2 893700 BLAKE2B 16b6aa20e510ef5661e1d0e172864ae00826bae7ba2b777b0160a7a5760b30b70891bb08ec78d32875580cdc4118ee7e89d6b3ee2dfd60a8ea73b61a4b4199a2 SHA512 e8d339fa266e637bc9b16095c65cc75239f7f6cb2bdc93c9453ec6bc5d47018e81b3aa96fac4ae89545d059ce3de62951d358429e874ffede75f99ac9d80ba2d

xfce-base/libxfce4ui/libxfce4ui-4.17.7.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://gitlab.xfce.org/xfce/libxfce4ui/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade +introspection startup-notification system-info vala"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3[introspection?,X]
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.17.2:=[introspection?]
+	>=xfce-base/xfconf-4.12:=
+	glade? ( dev-util/glade:3.10 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	startup-notification? ( x11-libs/startup-notification )
+	system-info? (
+		dev-libs/libgudev
+		gnome-base/libgtop
+		>=media-libs/libepoxy-1.2
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable system-info glibtop)
+		$(use_enable system-info epoxy)
+		$(use_enable system-info gudev)
+		$(use_enable startup-notification)
+		$(use_enable vala)
+		$(use_enable glade gladeui2)
+		--with-vendor-info=Gentoo
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}