gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-23 16:49:10 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/scikit-build: Bump to 0.16.4

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-12-17 12:13:27 +01:00
parent 934b39321d
commit 775acd2f7d
2 changed files with 70 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/scikit-build/Manifest
View File

@@ -1,2 +1,3 @@
DIST scikit-build-0.16.2.tar.gz 269822 BLAKE2B 4fe7d8f3c3a993f1832d94896068b6bede1eededb4d85e3332137f516819d167102a1eb2fde6dfe4ad187d0483a4e962311a4ca56f3aa5a4eff0c96a187ca052 SHA512 ae8dfd74c638e5cda127b24070c4e491ec51a69b35eae476f5f74a54ba97419d69e984ae7dc132782c77472852358d9d984650db4e6984decad74aadceecfa05
DIST scikit-build-0.16.3.tar.gz 270429 BLAKE2B 32930041e64750dc4ee7d496bf6541bcc3f75c5fbddadb95d3424eec2309381ac6cb67252936fa753b0996db44749d19662575f4f20f174f85c44256d91ec7b7 SHA512 8cec7b01b7a2b892c05a910806b0a3664f5a966165f1a87e9943067afc9b2a2e93657a7a68e47df6578d5d03f1ff0a0bd987e97cf4b0f442d79949f52247968c
DIST scikit-build-0.16.4.tar.gz 271037 BLAKE2B 6cca8a3c4f4b37228b77ac098650a5eca4ad0f525ca7dcba178f4cffabb7e60e9a7bbba244e64c1a598ab5916f2f47788198eb2a19803d8d0cf7b9792f4e06e2 SHA512 90315ceac4c372e4d7248b4b56b6092362c2c43fbdc180d1a234e057209c508a05d2c6e0a3d0c2587c3adb8957e4c66d5c171a2a2bc3dbf9874a0de58d97d976

69
dev-python/scikit-build/scikit-build-0.16.4.ebuild Normal file
View File

@@ -0,0 +1,69 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1
DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
HOMEPAGE="
https://github.com/scikit-build/scikit-build/
https://pypi.org/project/scikit-build/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/distro[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/cython[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/virtualenv[${PYTHON_USEDEP}]
)
"
distutils_enable_sphinx docs \
dev-python/sphinx_rtd_theme \
dev-python/sphinx-issues
distutils_enable_tests pytest
src_prepare() {
# not packaged
sed -i -e '/cmakedomain/d' docs/conf.py || die
distutils-r1_src_prepare
}
python_test() {
local EPYTEST_DESELECT=(
# sandbox violations
tests/test_hello_cpp.py::test_hello_develop
tests/test_issue274_support_default_package_dir.py
tests/test_issue274_support_one_package_without_package_dir.py
tests/test_issue334_configure_cmakelists_non_cp1252_encoding.py
tests/test_pep518.py
# This fails because of additional item setup.py in sources
tests/test_include_exclude_data.py::test_hello_sdist
tests/test_include_exclude_data.py::test_hello_sdist_with_base
tests/test_issue401_sdist_with_symlinks.py::test_sdist_with_symlinks
tests/test_manifest_in.py::test_manifest_in_sdist
# Wants internet to install things with pip
tests/test_numpy.py::test_pep518_findpython
# TODO
"tests/test_command_line.py::test_hide_listing[True-bdist_wheel]"
)
epytest
}