dev-util/rosdep: bump to 0.22.1

Signed-off-by: Alexis Ballier <aballier@gentoo.org>

dev-util/rosdep/Manifest

@@ -1 +1,2 @@
 DIST rosdep-0.21.0.tar.gz 312028 BLAKE2B 7ad3bfe027c574fdc82952085a5ea447e811b6858fca13121ad25cf1bda04e33091782b69c4a8f9a71383f1716678bd19c8752600987f7c41016ee93eed1ddcb SHA512 fb784c1603087b62444d767f1ce9e45303d2161e69ac82fec0edeeefd99f0c70e14b25b64a516df01e72aaa3a1b4a25b9507855edaa169c3af945e6581d9751d
+DIST rosdep-0.22.1.tar.gz 313822 BLAKE2B 537756d107e0cdea2333743bf387cfacde295a1cd368d212800fcfc9a967861b5ecd0a30e9ad53870fce7ea69d604650bb74d7331b3eb46adacffe9c2b8a0b57 SHA512 62964b2ca876cdf0cb392ba7b15a0bc5f5a735469fa9abfd0a0b0117a99fa47d5f8b7a415d9d0b7ebce1d399a964b6ee12d46c2ace8ff856cb17f2153f5cabd3

dev-util/rosdep/rosdep-0.22.1.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Command-line tool for installing ROS system dependencies"
+HOMEPAGE="https://wiki.ros.org/rosdep"
+
+if [[ ${PV} = *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/ros-infrastructure/rosdep"
+	inherit git-r3
+else
+	SRC_URI="http://download.ros.org/downloads/${PN}/${P}.tar.gz
+		https://github.com/ros-infrastructure/rosdep/archive/${PV}.tar.gz -> ${P}.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+# Tests need network
+RESTRICT="test"
+PROPERTIES="test_network"
+
+RDEPEND="
+	dev-python/catkin_pkg[${PYTHON_USEDEP}]
+	dev-python/rospkg[${PYTHON_USEDEP}]
+	dev-python/rosdistro[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+PATCHES=( "${FILESDIR}/tests.patch" )
+
+distutils_enable_tests pytest
+
+src_test() {
+	unset ROS_DISTRO
+	distutils-r1_src_test
+}
+
+pkg_postrm() {
+	if [ "${ROOT:-/}" = "/" ] ; then
+		einfo "Removing rosdep default sources list."
+		rm -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list"
+	fi
+}
+
+pkg_postinst() {
+	if [ "${ROOT:-/}" = "/" -a ! -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list" ] ; then
+		einfo "Initializing rosdep"
+		rosdep init
+	fi
+}