mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
media-libs/lilv: bump to 0.24.14, added python3_11
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST lilv-0.24.12.tar.bz2 427404 BLAKE2B 47efe553c6fc249ed0cde47a47a01e0b3496ea4dfac88849b75d9720cb3a158fa1c95959ffc1a09e606f8ba3831e79382ba08ad100ee17cf19c7f1ffa186d6e2 SHA512 ea22db4e995792b62d60d793169c792549b8fb0255c2cf7a85780dd149811921e2fae5eaea0fb83465f01b14dfa66361af3be40bf7cb3733e98655b943f4faee
|
||||
DIST lilv-0.24.14.tar.bz2 428004 BLAKE2B bc84fe5a4bf34f88ea7f9c09cb3168186f7f0fd2f3f23b08f55100502d959fd74fe7e1c6d9307772b1983fbeedde100f75d6751e9bf92a9663aaaa115ca0770c SHA512 f266e91f3cbc325c25dd7d08bde5033091cb3072c2dcb1490e9474f562b798dbc71c45ca7d971ed4dfd6bb16f5f6725ae242a58c4486684b71350e73f1469f47
|
||||
|
||||
@@ -0,0 +1,80 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..11} )
|
||||
PYTHON_REQ_USE='threads(+)'
|
||||
|
||||
inherit python-single-r1 waf-utils bash-completion-r1 multilib-build multilib-minimal
|
||||
|
||||
DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
|
||||
HOMEPAGE="http://drobilla.net/software/lilv/"
|
||||
SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
|
||||
|
||||
LICENSE="ISC"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
|
||||
IUSE="doc +dyn-manifest static-libs test"
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="
|
||||
virtual/pkgconfig
|
||||
doc? (
|
||||
app-doc/doxygen
|
||||
dev-python/sphinx
|
||||
dev-python/sphinx_lv2_theme
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
dev-libs/serd[${MULTILIB_USEDEP}]
|
||||
dev-libs/sord[${MULTILIB_USEDEP}]
|
||||
media-libs/libsndfile
|
||||
media-libs/lv2[${MULTILIB_USEDEP}]
|
||||
media-libs/sratom[${MULTILIB_USEDEP}]
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
pkg_setup() {
|
||||
python_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
|
||||
multilib_copy_sources
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
waf-utils_src_configure \
|
||||
--docdir="${EPREFIX}"/usr/share/doc/${PF} \
|
||||
--no-bash-completion \
|
||||
$(multilib_native_usex doc --docs "") \
|
||||
$(usex test --test "") \
|
||||
$(usex static-libs --static "") \
|
||||
$(usex dyn-manifest --dyn-manifest "")
|
||||
}
|
||||
|
||||
multilib_src_compile() {
|
||||
./waf build || die
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
./waf test || die
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
waf-utils_src_install
|
||||
}
|
||||
|
||||
multilib_src_install_all() {
|
||||
sed -i "/lv2jack/d" utils/lilv.bash_completion
|
||||
newbashcomp utils/lilv.bash_completion lv2info
|
||||
|
||||
dodir /etc/env.d
|
||||
echo "LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2" > "${ED}/etc/env.d/60lv2"
|
||||
|
||||
python_optimize
|
||||
}
|
||||
Reference in New Issue
Block a user