dev-python/python-neutronclient: Bump to 12.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-neutronclient/Manifest

@@ -1 +1,2 @@
 DIST python_neutronclient-11.8.0.tar.gz 213135 BLAKE2B fc38678c2e5f922096e84f4c11f4a6bb07ec4dff3caac94d1a858ea29e0e28c934312c0c0ca9fc7534decd5509904a58dc346dd74256152acc7ce72d01fffee6 SHA512 2b83f4cd336190f4872e5dc53a3b0bbdf8736d6e1704c07dac83fc5f218b0b213105067cdbd35e2f1f76062909304da0bf4efd0482f2fe7ab3b2a7cd1fe10143
+DIST python_neutronclient-12.0.0.tar.gz 185697 BLAKE2B 18e21a98eef52f487796a6d4a517d1468bf7140f49426cb2b7e70dcff7245d47565944b5981f29ca2bbfda35a8d2c872639064b04369780b07f43a3074cff908 SHA512 e85793c58cd55974be6fe215d9b08d1776111c523e0dcf3d5c93718cb7d8387e0dc91714971adcdd21e33f9d4fb583640f46a7700a506c76fc16f6493c1628da

dev-python/python-neutronclient/python-neutronclient-12.0.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-neutronclient/
+	https://github.com/openstack/python-neutronclient/
+	https://pypi.org/project/python-neutronclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslotest[${PYTHON_USEDEP}]
+		dev-python/python-openstackclient[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Needs osprofile
+	rm neutronclient/tests/unit/test_http.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b neutronclient.tests.unit
+}
+
+python_install() {
+	distutils-r1_python_install
+	# stupid stupid stupid
+	local SITEDIR="${D}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.dist-info )
+	[[ -d ${egg[0]} ]] || die "python_quantumclient*.dist-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}