xfce-extra/xfce4-whiskermenu-plugin: Bump to 2.8.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-whiskermenu-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-whiskermenu-plugin-2.8.3.tar.bz2 188399 BLAKE2B 75436820471e694eca05a02b93eafe3f050d5e5caa35e975329c85840650b716a15bb549703d2a91ff5871af0f24b19d99e8f032c29ade784d73702c1ea0a46f SHA512 ef4fe09fe69f1d6a5b0ab54a6cae48319c859b6b9d16facf39631814986d852913410a1ca1b32cfa7b355dafa78a6d91c12843b0c685e24bf168d6065a5f6099
+DIST xfce4-whiskermenu-plugin-2.8.4.tar.bz2 189895 BLAKE2B 6f6536c5fe83ead7d2a706846b248e13bec45af2e1ed66e4e880f75813640e588a71ada71af97f62c4d358add15a97b5c97cd06cef150a08785b97d36ffa2b50 SHA512 6033664aa80ccf82cb9abcd4918f027f731f5d065acc4462330f769f94e3dea7036199cdf88f84d2f244e9b1279d5aba2a7a14aa20ef41983c718180a16d548b

xfce-extra/xfce4-whiskermenu-plugin/xfce4-whiskermenu-plugin-2.8.4.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake xdg-utils
+
+DESCRIPTION="Alternate application launcher for Xfce"
+HOMEPAGE="https://gottcode.org/xfce4-whiskermenu-plugin/"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="accountsservice wayland"
+
+DEPEND="
+	virtual/libintl
+	x11-libs/gtk+:3
+	>=xfce-base/exo-0.12:=
+	>=xfce-base/garcon-0.6.4:=
+	>=xfce-base/libxfce4ui-4.14:=
+	>=xfce-base/libxfce4util-4.14:=
+	>=xfce-base/xfce4-panel-4.14:=
+	>=xfce-base/xfconf-4.14:=
+	accountsservice? (
+		>=sys-apps/accountsservice-0.6.45
+	)
+	wayland? (
+		>=gui-libs/gtk-layer-shell-0.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+# upstream does fancy stuff in other build types
+CMAKE_BUILD_TYPE=Debug
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_AS_NEEDED=OFF
+		-DENABLE_LINKER_OPTIMIZED_HASH_TABLES=OFF
+		-DENABLE_DEVELOPER_MODE=OFF
+		-DENABLE_LINK_TIME_OPTIMIZATION=OFF
+		-DENABLE_ACCOUNTS_SERVICE=$(usex accountsservice)
+		-DENABLE_GTK_LAYER_SHELL=$(usex wayland)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}