dev-java/openjdk-jre-bin: add 8.322_p06

Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,2 +1,3 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.14_9.tar.gz 42435138 BLAKE2B 0f972a78221b74be4b8c87845f52d331eb6caf84eef06d291d0cd25ce4357b7072f938fd0390a9c54647d4ddcfe4c0184ddf84583e017e1bf78338b7939437bc SHA512 9ee64498d83d16cefc5a155393d9477bb78338d43a3b4b1699f4358644415a6be5601f7b2a87a82f2a95cafd6485b6db7b30bd0d21096110211b942e95deed64
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u312b07.tar.gz 41286015 BLAKE2B f555fee173b8af98f64cdd08b8141c823033473d8fa0601f8e69899bc6b82234ac33a6de45f87b2cd9457e22d500da9052209c45798d47ec3c4a34496b30d154 SHA512 36d07389e63e49ee16f1329aa7e0bd5b42b397f864f10080038017920fd2b178d5cd9dfaef157080ac020721d0e6e7b26b0277ab1cde69c20500fc34bab0e915
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u322b06.tar.gz 41317897 BLAKE2B b96b39d4b3f7fe54f9b04698d4f24879ce617e61ade298b7de1472cb85fbf7d5f297f009c0e881a17bcdaf9baaf3187acef531b0ace97a1f2ab099811995c815 SHA512 4a3acc1330056011f0097aaca77858779e2c89d214598ef66736956984204b8de804549e42c51f8392806753f3d534d34ad93ef6df9f2f45a369e04f6a0694ac

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.322_p06.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="amd64"
+
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}/${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}