gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-17 02:39:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/trimesh: Bump to 3.10.6

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-03-25 00:18:38 +01:00
parent fd5eec3bd1
commit 765421bb3a
2 changed files with 63 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/trimesh/Manifest
View File

@@ -2,3 +2,4 @@ DIST trimesh-3.10.0.tar.gz 10736418 BLAKE2B 9e65e9e5bc3984d1dca5c5d4a0498ff1f635
DIST trimesh-3.10.1.tar.gz 10738596 BLAKE2B 9dc310b3e2b26fcf85f8c15841e5db1cf0edfb52593b3d89ee7ccb0678df2e9261f79cc9ed6709b5cad2ed633b220daa4f0fcb88da27bd942d1973d89968f147 SHA512 555777569c5bbfda2b93cc52ec21dfb9efecda30f3c0283415249a742b3717df8dcea9ce9cf79e42419d1bdafcad34795dd198f80b5e8a791f7cfb1a9cc2a17a
DIST trimesh-3.10.2.gh.tar.gz 10738967 BLAKE2B 70aecc2d7524eec7eb5499f2926072139bab26cadd24a7f2200975ba1d15d7ee2a264efa124be69669f70c2a3026aa67ff3c6f56156dbf940027b48b57de4f9f SHA512 3fed75b26187dc8b682e7befd7c23c96a33cb3375255a26b3c80513d8ea9b2308f7570940a8c11da1455bd7acf5b89aead65a9743d76d2adf8e6faf5260a6b77
DIST trimesh-3.10.3.gh.tar.gz 10739164 BLAKE2B 558e9b66b6398b10ffaa1117f07d1ea7464d5e230d201473cf24efbb2e88e534883cc33fc13a6e217f76d5d40dc5f507b5fdca73f4275a79e67ac8a654c8199d SHA512 0f20e77bb4c94a723aa50a15cb0c401d410d4112ef936e4340ad45ca2b88ee42881a02c280bc51635f443c4c38078db218b334405c3de9fc7236f6bc3cef3855
DIST trimesh-3.10.6.gh.tar.gz 10740778 BLAKE2B 3e0b456f44b557d0176e8c2bcde36e49c01c2d95468329453dd4bbbc3253d2f2a2e5ad6ee3201def0c8c657e9521fcad9d2b33c43fc1d44337cca3b0ec6f1826 SHA512 df83d2b31f33d448ab321cf32c8ca37689ca201dbd8a963166e33be8266120db9ac4749c7360f3739f8289a755a7d40ea2c4b09cd4c2e07851adce0be743081c

62
dev-python/trimesh/trimesh-3.10.6.ebuild Normal file
View File

@@ -0,0 +1,62 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 multiprocessing optfeature
DESCRIPTION="Python library for loading and using triangular meshes"
HOMEPAGE="https://trimsh.org/ https://github.com/mikedh/trimesh"
# No tests in PyPI tarballs
SRC_URI="
https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
RDEPEND="
dev-python/chardet[${PYTHON_USEDEP}]
dev-python/colorlog[${PYTHON_USEDEP}]
dev-python/jsonschema[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/msgpack[${PYTHON_USEDEP}]
dev-python/networkx[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pycollada[${PYTHON_USEDEP}]
dev-python/pyglet[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/svg-path[${PYTHON_USEDEP}]
dev-python/sympy[${PYTHON_USEDEP}]
dev-python/xxhash[${PYTHON_USEDEP}]
sci-libs/rtree[${PYTHON_USEDEP}]
sci-libs/shapely[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
}
pkg_postinst() {
optfeature_header "${PN} functionality can be extended by installing the following packages:"
optfeature "making GUI applications with 3D stuff" dev-python/glooey
optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
optfeature "loading a number of additional mesh formats" dev-python/meshio
optfeature "figuring out how much memory we have" dev-python/psutil
optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
}