sci-electronics/klayout: Version bump

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

sci-electronics/klayout/Manifest

@@ -1 +1,2 @@
 DIST klayout-0.26.5.tar.gz 52335763 BLAKE2B b1ab39c378ce23c28f5a58191dbf43c5b8c165e9df241b00573c8f8b72a5a7251cddd41bf62a7e37f59cad68024c52ab99f8d0f10bf1bf45dba975bf37ba80db SHA512 b80dff34a9dd538921f6863fc94eb8a2160b989468ec0493a7ecfdfccea0e4f0441aa1ee860d000b150b0a0bc0b831dcb849ab77e9eb1304e9ed6fcced94689c
+DIST klayout-0.26.8.tar.gz 54423228 BLAKE2B 5839e77a7910b0a838b6d1f436fe697ea445e968044f7102ab71d3d485ea4631194bf002d4440771e73c77359b673372662506a9cc6e2d4a3b5dc8df171783c7 SHA512 a37b324194ed523ee70a1d63034db9ba48cf55d44d3a9d1bc612803cde2425f6909fd0571ad4a66318fc2c6735e19ba11a26ab153e1200adec405c16fc05f144

sci-electronics/klayout/klayout-0.26.8.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+RUBY_OPTIONAL=no
+USE_RUBY="ruby26"
+# note: define maximally ONE implementation here
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit toolchain-funcs python-single-r1 ruby-ng
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/klayoutmatthias/${PN}.git"
+	inherit git-r3
+	EGIT_CHECKOUT_DIR=${WORKDIR}/all/${P}
+else
+	SRC_URI="https://www.klayout.org/downloads/source/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
+HOMEPAGE="https://www.klayout.de/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	sys-libs/zlib
+	${PYTHON_DEPS}
+	$(ruby_implementations_depend)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ruby-ng_pkg_setup
+}
+
+each_ruby_configure() {
+	tc-export CC CXX AR LD RANLIB
+	export CFLAGS CXXFLAGS
+	./build.sh \
+		-expert \
+		-dry-run \
+		-qmake "/usr/$(get_libdir)/qt5/bin/qmake" \
+		-ruby "${RUBY}" \
+		-python "${PYTHON}" \
+		-build . \
+		-bin "${T}/bin" \
+		-rpath "/usr/$(get_libdir)/klayout" \
+		-option "${MAKEOPTS}" \
+		-with-qtbinding \
+		-without-64bit-coord \
+		-qt5 || die "Configuration failed"
+}
+
+each_ruby_compile() {
+	emake all
+}
+
+each_ruby_install() {
+	emake install
+
+	cd "${T}/bin" || die
+
+	dodir "/usr/$(get_libdir)/klayout"
+	mv lib* lay_plugins db_plugins "${ED}/usr/$(get_libdir)/klayout/" || die
+
+	mkdir -p "${D}/$(python_get_sitedir)" || die
+	mv pymod/* "${D}/$(python_get_sitedir)/" || die
+	rmdir pymod || die
+
+	dobin *
+
+	python_optimize
+}

sci-electronics/klayout/klayout-9999.ebuild

@@ -4,7 +4,7 @@
 EAPI=7
 
 RUBY_OPTIONAL=no
-USE_RUBY="ruby25"
+USE_RUBY="ruby26"
 # note: define maximally ONE implementation here
 
 PYTHON_COMPAT=( python3_{6,7,8} )