gui-apps/uwsm: add 0.23.0

Signed-off-by: Kenton Groombridge <concord@gentoo.org>

gui-apps/uwsm/Manifest

@@ -1 +1,2 @@
 DIST uwsm-0.21.5.tar.gz 98122 BLAKE2B 027d49fc892514fe333d4404aa307bf3c0b1849b6fc4326ff55971aac2d177642ff86da86301b26cb0b8980694eabbdbc300ebd1dfb3419784f3c1bd461a7e3c SHA512 d005a2dc4af73f5edfbdbe4e4f5657f078c22110ff26e8fda451cc4d1ac1995f2c36d9480ea7b89e830070da69b35a3bd60048f45d22b77e30156a7e0a718e32
+DIST uwsm-0.23.0.tar.gz 104550 BLAKE2B 5866709d50bcd2b6378b0ed9e0f65312fc13d88eea0d1a14d66b85e129bd82bc70bf4c9506cdbfc8455f74b7b9d0258e24e44de00a79d3076ccb4ad720c8e66b SHA512 018b0d8af648c72ed83e15044cc8356e527b8f6388ebfec263d2c7d5aa2a835831ffdda02cc5d1e60eece3f72261241ed107adaefcf59d2b949c5b98e2c64572

gui-apps/uwsm/uwsm-0.23.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+inherit meson optfeature python-single-r1
+
+DESCRIPTION="Universal Wayland Session Manager"
+HOMEPAGE="https://github.com/Vladimir-csp/uwsm"
+SRC_URI="https://github.com/Vladimir-csp/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+man"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="${DEPEND}"
+BDEPEND="man? ( app-text/scdoc )"
+
+src_configure() {
+	local emesonargs=(
+		-Duuctl=enabled
+		-Dfumon=enabled
+		-Duwsm-app=enabled
+		$(meson_feature man man-pages)
+		-Ddocdir=/usr/share/doc/"${PF}"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}/usr/bin"
+	python_optimize "${ED}/usr/share/${PN}"
+}
+
+pkg_postinst() {
+	optfeature "TUI selection menu feature" dev-libs/newt
+	optfeature "GUI selection menu for uuctl" gui-apps/wofi
+	optfeature "GUI selection menu for uuctl" x11-misc/dmenu
+	optfeature "GUI selection menu for uuctl" x11-misc/rofi
+	optfeature "notifications from uwsm commands and services (notify-send)" x11-libs/libnotify
+}