games-engines/stratagus: version bump to 2.4.1.

Also remove deprecated games.eclass and bump EAPI 6 to version.

Package-Manager: Portage-2.3.10, Repoman-2.3.3
Signed-off-by: Marty E. Plummer <hanetzer@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/5779

games-engines/stratagus/Manifest

@@ -1 +1,2 @@
+DIST stratagus-2.4.1.tar.gz 1087678 SHA256 4f77d0e3cb09c6322a9d5576b55bc2eb498e041a4d77c79dfc3a9b5612913788 SHA512 1f0420677df72e3e2d2f31e60030fa2eba4c3d1ab80cfc79c045724fe39ac237846bc38e8762ee9aa51768a443cdbbaa1fe91bf80fb2164261288a1bb17e27cd WHIRLPOOL 47bef0b10e0bbcab840cf48c5f85e75532f4c6d78bda75b846f711b35b255f5594647df3db736637a46c28b2d08722591223b05fc1d81fb66e93ad9377a0ae02
 DIST stratagus_2.3.0.orig.tar.gz 1000990 SHA256 d3d124f253e987ee1be396ebcdec31228790163a121a9f4e0049d334114adb99 SHA512 ad38568029aa777fcc2d2e6d4a862b4192bc87354b23712270b9f0a62e269548a08097305e97adcea7bc9d9d506a6d092c578656a1957db808a48f44712a76bf WHIRLPOOL 705ab071fff4dc6d865d8e14c67bf3ef1e64fde45a85115178b4686d3c066907e193d733f5f9d09ec363660925349097f83afa6895a8c27e73c680e27db357a9

games-engines/stratagus/stratagus-2.4.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils
+
+DESCRIPTION="A realtime strategy game engine"
+HOMEPAGE="https://launchpad.net/stratagus/"
+SRC_URI="https://github.com/Wargus/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bzip2 debug doc fluidsynth mikmod mng theora vorbis"
+
+RDEPEND="dev-db/sqlite:3
+	>=dev-lang/lua-5:0
+	dev-lua/toluapp
+	media-libs/libpng:0
+	virtual/opengl
+	x11-libs/libX11
+	media-libs/libsdl[sound,opengl,video]
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	fluidsynth? ( media-sound/fluidsynth )
+	mikmod? ( media-libs/libmikmod )
+	mng? ( media-libs/libmng )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+		theora? ( media-libs/libtheora )
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig"
+
+REQUIRED_USE="theora? ( vorbis )"
+PATCHES=(
+	"${FILESDIR}/${PN}"-2.3.0-debug.patch
+	"${FILESDIR}/${PN}"-2.3.0-doc.patch
+)
+
+src_configure() {
+	# there are in-source switches
+	use debug && CMAKE_BUILD_TYPE=Debug
+
+	local mycmakeargs=(
+		-DGAMEDIR="/usr/bin"
+		-DDOCDIR="/usr/share/doc/${PF}"
+		-DWITH_BZIP2=$(usex bzip2)
+		-DENABLE_DOC=$(usex doc)
+		-DWITH_FLUIDSYNTH=$(usex fluidsynth)
+		-DWITH_MIKMOD=$(usex mikmod)
+		-DWITH_MNG=$(usex mng)
+		-DWITH_OGGVORBIS=$(usex vorbis)
+		-DWITH_THEORA=$(usex theora)
+		-DENABLE_DEV=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+}