gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

kde-apps/ark: drop 23.08.5

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2024-09-20 19:57:47 +02:00
parent 7de683ff6e
commit 75582fa701
2 changed files with 0 additions and 81 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/ark/Manifest
View File

@@ -1,3 +1,2 @@
DIST ark-23.08.5.tar.xz 3018696 BLAKE2B 482a17aa9bf72abbaa75510451ba0dd59812d2cd2aca97efda0f4f1c78f98060d9f654efd0387aeae35d5220304f00139520a6836451056b84064cc8d8b12d16 SHA512 8fab4281f5cfe34938f7a958e2889ad4dabff6613b1e3a8fed1efb2039dbf35a71d99494869037fd821515ecfba6e44304bb0907c27afd646fe7496783735336
DIST ark-24.05.2.tar.xz 3002644 BLAKE2B 9cb3108e528ca1e883445d2160bee25390d2c729cb1057cd48d33b996621421d25ea620380783d3e3b9280e9104f2e16164c6840a43c7e4e08e3ca2df5bb4c7e SHA512 d550c14ee12dc3a20933ee05117839f05f5ff664d63b9570640a1d635ec69cfdccab8f1f25b8a8ee34acd75916f4d8ab60b3c622098432fc276128288e26f534
DIST ark-24.08.1.tar.xz 3003728 BLAKE2B 3da6add6116c9e43bd007ca7b7a558c09811d5b0b5cd182903aab81628f6b851d3176d9776ac59644f9f84b3eacb34ef5010504b3634a85c48e306016623491e SHA512 0eacd3eb90355d5df95e519aa3ce2323b5378a12e8b88667dd236bd4e3da1737f0f9ff38ddd08070356804c312841e350ad8b84edc1b6fc00250e7304745b49e

80
kde-apps/ark/ark-23.08.5.ebuild
View File

@@ -1,80 +0,0 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
ECM_TEST="optional"
KFMIN=5.106.0
QTMIN=5.15.9
inherit ecm gear.kde.org optfeature
DESCRIPTION="File archiver by KDE"
HOMEPAGE="https://apps.kde.org/ark/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="amd64 arm64 ~loong ~ppc64 ~riscv x86"
IUSE="zip"
RDEPEND="
>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kpty-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
sys-libs/zlib
zip? ( >=dev-libs/libzip-1.6.0:= )
"
DEPEND="${RDEPEND}
>=dev-qt/qtconcurrent-${QTMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
test? ( >=dev-libs/libzip-1.6.0:= )
"
# app-arch/rar is binary only
BDEPEND="
sys-devel/gettext
elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
"
CMAKE_SKIP_TESTS=(
# bug 822177: may segfault or hang indefinitely
kerfuffle-addtoarchivetest
# bug 827840: continuously broken with translations installed
plugins-clirartest
# bug 927184: requires DBus
app-batchextracttest
)
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package zip LibZip)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "rar archive creation/extraction" "app-arch/rar"
optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
optfeature "7-Zip archive support" "app-arch/p7zip"
optfeature "lrz archive support" "app-arch/lrzip"
optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
fi
ecm_pkg_postinst
}