sci-libs/scikit-learn: add 1.3.2

Bug: https://bugs.gentoo.org/911369
Closes: https://bugs.gentoo.org/910258
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

sci-libs/scikit-learn/Manifest

@@ -1 +1,2 @@
 DIST scikit-learn-1.1.2.gh.tar.gz 7104556 BLAKE2B e67e1deddf5a1134b57a146e8271a406cb257ffc92c9719e90f5b9d98e711b68bc67e3367660ecaad61aaec1794bb8999b4dd00b7d56e21eca8fcb2ee72cc9aa SHA512 58789c1e607d7de3339fa3b8928553ca96cef93e8da8fd13612aa78e5ebde8e6a55e3bf7845f9a45b78ed77da6a219d08d2c26318b602f937e0e3debd239293e
+DIST scikit-learn-1.3.2.gh.tar.gz 7650823 BLAKE2B 170699917f46d6d3f4b9ebc314bc1ec45687dad0a4aec5d2cee6e288b5dbe508bad6dd80406501f289a33593c6482067393e9dc28155f85a4872a34523bf4199 SHA512 a3799e9b39b755a50ba225f836904a378f7d83a08274c614d0485e4d4d4a7b0c7adba2dbb6612f2ccb4e5167f872214a2853eff69d767dc70f52369bda7a230b

sci-libs/scikit-learn/scikit-learn-1.3.2.ebuild

@@ -0,0 +1,60 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="https://scikit-learn.org/stable/"
+SRC_URI="https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/wheel[${PYTHON_USEDEP}]
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	sci-libs/scikit-image
+
+python_test() {
+	# This needs to be run in the install dir
+	cd "${WORKDIR}/${P}-${EPYTHON//./_}/install/usr/lib/${EPYTHON}/site-packages/sklearn" || die
+	distutils-r1_python_test
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}