games-board/cockatrice: Bump to 20230914

Closes: https://bugs.gentoo.org/918619
Closes: https://bugs.gentoo.org/739118
Closes: https://bugs.gentoo.org/843257
Closes: https://bugs.gentoo.org/912942
Signed-off-by: Guillaume Seren <guillaumeseren@gmail.com>
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

games-board/cockatrice/Manifest

@@ -1 +1,2 @@
 DIST cockatrice-20210126.tar.gz 8589061 BLAKE2B f90840f2b6044ea364101410adc9481660a7247460f7191d6b022e447cc1685f28384a39596a3fbeaeb67f1af0cc184cf017f8e666e67e673672bc3968ac807a SHA512 e07cdee72c8bf4755d49cac69bd6a2ddb4c168d370ed4a1cbd341537184869ee8680fbf5e9d6b636c7c68888a8d00f474bae9cf245303d638b3aac8762f9fa8e
+DIST cockatrice-20230914.tar.gz 9295150 BLAKE2B b4dbe0ab8afb8871c63ca844dddcd540181a1cbfae3af3603f9677f6cbd871603527de8dc6ac148423457c227bcfd291c7db804607d1b8986dcb23138510eec6 SHA512 06841d1aabd14afef8d041e9c9eb1f157f9db1e8440d35b6092ffc68007599bf1b4185ec90e40074d562097d2230985087c4e9531b3e004eab221060c4076c57

games-board/cockatrice/cockatrice-20230914.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg cmake optfeature
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}-Release-2.9.0"
+
+DESCRIPTION="Open-source multiplatform software for playing card games over a network"
+HOMEPAGE="https://github.com/Cockatrice/Cockatrice"
+SRC_URI="https://github.com/Cockatrice/Cockatrice/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/Cockatrice-${MY_PV}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+client +oracle test server"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/protobuf:=
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	client? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwebsockets:5
+	)
+	oracle? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtsvg:5
+		sys-libs/zlib
+		app-arch/xz-utils
+	)
+	server? (
+		dev-qt/qtsql:5
+		dev-qt/qtwebsockets:5
+	)"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )"
+BDEPEND="
+	dev-libs/protobuf:="
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.9.0-support-protobuf-23.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=OFF # This is need because the default eclass breaks the build
+		-DUSE_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client)
+		-DWITH_ORACLE=$(usex oracle)
+		-DWITH_SERVER=$(usex server)
+		-DTEST=$(usex test)
+		-DICONDIR="${EPREFIX}/usr/share/icons"
+		-DDESKTOPDIR="${EPREFIX}/usr/share/applications"
+		-DFORCE_USE_QT5=1
+		-DUPDATE_TRANSLATIONS=OFF
+	)
+
+	# Add date in the help about, come from git originally
+	sed -e 's/^set(PROJECT_VERSION_FRIENDLY.*/set(PROJECT_VERSION_FRIENDLY \"'${MY_PV}'\")/' \
+		-i cmake/getversion.cmake || die "sed failed!"
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "mysql/mariadb support" dev-db/mysql-connector-c
+}