net-libs/libtorrent: Bump to 0.16.6

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://github.com/gentoo/gentoo/pull/45299
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Nicolas PARLANT
2026-01-10 12:46:13 +00:00
committed by Sam James
parent c7f071026e
commit 7500a4a352
2 changed files with 71 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST libtorrent-0.15.7.tar.gz 872380 BLAKE2B 58188897a04a749b6d6e201c6da460952aff5e55231131dc29bd0a008cde0e5a39a1bc8eaaf90a7aa3ae160b2c961d40ba1de42f800f46871d835670746ef0b8 SHA512 53f8904f267b1fbfb9aa52ae5ec8740fee23ff3d3e3b115b4937aec3f27a233d0d11d9c56c4fbbad0078f66920759c23ae5e70c8e2129b05aff597735d0ba4ec
DIST libtorrent-0.16.5.tar.gz 887247 BLAKE2B ae17c70f0271740a0fef7daad5903356413ec2b434933300d26cb0c9e1d0220728bdb17c58b9799d9bb860b4c9972e75ed03ce54b38b4769479ab82ecb1d7c3a SHA512 e7638aef32e453c5b631b7a631cce6413ae36138b062eb1bfa2ebc5a599dfaeff2a935e46972aa160a2f35c303a9b9c7ffed6a521e75fd1f3a45507c9069d00a
DIST libtorrent-0.16.6.tar.gz 887531 BLAKE2B 874595b09cdd623ff4669c7bf7e818081f8507af18b1b06ec1f977aed674366491f5797b95c10975661643a98aea037cf0a2bc1cebd81b8851aa4172402ffbfe SHA512 0742483787244915c6aba2c8db3001d8cae2e8e890bfe335614c83a69c0e203bde8896c6db2547e88bacc83379e764a76d42f9406febce810ec068730fb29a12
@@ -0,0 +1,70 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
DESCRIPTION="BitTorrent library written in C++ for *nix"
HOMEPAGE="https://rtorrent.net"
if [[ ${PV} == *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/rakshasa/${PN}.git"
else
SRC_URI="https://github.com/rakshasa/rtorrent/releases/download/v${PV}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x64-solaris"
fi
LICENSE="GPL-2"
# The README says that the library ABI is not yet stable and dependencies on
# the library should be an explicit, syncronized version until the library
# has had more time to mature. Until it matures we should not include a soname
# subslot.
SLOT="0"
IUSE="debug test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/openssl:=
net-libs/udns
net-misc/curl
virtual/zlib:=
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? ( dev-util/cppunit )
"
src_prepare() {
default
# use system-udns
rm -r src/net/udns || die
sed -e 's@"net/udns/udns.h"@<udns.h>@' \
-e '\@^#include "net/udns/udns_.*.c"@d' \
-i src/net/udns_library.cc src/net/udns_library.h src/net/udns_resolver.cc || die
if [[ ${CHOST} != *-darwin* ]]; then
# syslibroot is only for macos, change to sysroot for others
sed -i 's/Wl,-syslibroot,/Wl,--sysroot,/' "${S}/scripts/common.m4" || die
fi
eautoreconf
}
src_configure() {
local myeconfargs=(
LIBS="-ludns"
--enable-aligned
$(use_enable debug)
--with-posix-fallocate
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" -type f -name '*.la' -delete || die
}