dev-ml/cudf: add 0.10

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ml/cudf/Manifest

@@ -1 +1,2 @@
 DIST cudf-0.9.tar.gz 55124 BLAKE2B 013f97d13b732674a7d0f9188590bbb8150ae9dc32ce26b56fb04848629fb27a3c850aa327e687d6aa80eb62ba6f67af2fcf86a647520e73d7f76748871a79cc SHA512 4abdd1a5a3d616273abe9dda87450a922ecd69b64d32f34d8fa3086bbd07fd23ffb01c24b128bf4d1c0c817cfa1da8029e743d33b3ad6a04e7a8f706b098c427
+DIST cudf-v0.10.tar.bz2 47664 BLAKE2B 6ecdfc4243d80f12f6904b334f93ff47beb94535b6ba84992c6a31d244a7c2dcb6072e67828d96b31d4628bb244022fd962efcdcae5299f5a57694f3aa6c95a8 SHA512 b36ecad224070d2c07d4123fb7e39160390ddec4196505e66aad9fbd982bd7ca320ff5f0e771e7996da49bff22fb87fc057060277695b75cd68de19e57cb3855

dev-ml/cudf/cudf-0.10.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit dune toolchain-funcs
+
+MYP=${PN}-v${PV}
+DESCRIPTION="Library to parse, pretty print, and evaluate CUDF documents"
+HOMEPAGE="http://www.mancoosi.org/cudf/"
+SRC_URI="https://gitlab.com/irill/${PN}/-/archive/v${PV}/${MYP}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0/${PV}"
+KEYWORDS="amd64 arm arm64 ~ppc ppc64 ~riscv x86"
+IUSE="+ocamlopt llvm-libunwind test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-lang/ocaml-3.12:=[ocamlopt?]
+	dev-ml/extlib:=
+	dev-ml/findlib:=
+	dev-libs/glib:2
+	llvm-libunwind? ( sys-libs/llvm-libunwind:= )
+	!llvm-libunwind? ( sys-libs/libunwind:= )
+	sys-libs/ncurses:=
+"
+DEPEND="${RDEPEND}
+	test? ( dev-ml/ounit2 )
+	dev-ml/ocamlbuild
+	dev-lang/perl
+"
+BDEPEND="virtual/pkgconfig"
+
+QA_FLAGS_IGNORED='.*'
+
+S="${WORKDIR}"/${MYP}
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		Makefile || die
+	sed -i \
+		-e 's|-lncurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind|g' \
+		-e "s|ar r|$(tc-getAR) r|g" \
+		c-lib/Makefile || die
+	sed -i \
+		-e 's|-lcurses|$(shell ${PKG_CONFIG} --libs ncurses glib-2.0) -lunwind|g' \
+		c-lib/Makefile.variants || die
+
+	tc-export CC PKG_CONFIG
+
+	sed -i \
+		-e "s|-lncurses|$( $(tc-getPKG_CONFIG) --libs ncurses)|g" \
+		c-lib/cudf.pc.in || die
+}
+
+src_compile() {
+	dune_src_compile
+	emake c-lib
+	if use ocamlopt ; then
+		emake c-lib-opt
+	fi
+}
+
+src_test() {
+	dune_src_test
+	emake c-lib-test
+}
+
+src_install() {
+	emake DESTDIR="${ED}" LIBDIR="/usr/$(get_libdir)" install
+	dodoc BUGS ChangeLog README TODO
+}

dev-ml/cudf/metadata.xml

@@ -9,4 +9,7 @@
 		<email>gienah@gentoo.org</email>
 		<name>Mark Wright</name>
 	</maintainer>
+	<upstream>
+		<remote-id type="gitlab">irill/cudf</remote-id>
+	</upstream>
 </pkgmetadata>