dev-util/blueprint-compiler: bump to 0.16.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
2025-01-22 17:20:52 +01:00
parent 15c6f3926c
commit 7459a83352
2 changed files with 83 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST blueprint-compiler-v0.14.0.tar.bz2 95515 BLAKE2B e5e4c721f76a9455d0f53b54e5b981cbd918959c206cad2b6fa47ba3a85bb1bcacb11d65b848cbde01ae32faa6f09c1f80cf6150ee436e359e7b1e9044822bb4 SHA512 3c2c422c6c41c408aff2b4342186e7a20eeb37489aff396d48c936f7a856e9d946f3d6fb6ad64a0fd933bdfc6bce546571d67c95b8f01af591c562d531c246c0
DIST blueprint-compiler-v0.16.0.tar.bz2 101391 BLAKE2B 6380f3aa3472ab0567e89acadf290e4954dbe640d5c4aaa6adfe3fb13ee50295c21dffcca1a4baccf3b5049429eae22d8953acc65dbef1904de01209226d0c88 SHA512 9c8b3da532f7d9a36fa0993da295438afe57a5da03e122f3d9cc715dd7b7d99f2be52416f19a7a8d8523516f4f799cbb0a2c9ffafdef58a66163857542e5c8d7
@@ -0,0 +1,82 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{11..13} )
inherit edo meson python-single-r1 virtualx
DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/
https://gitlab.gnome.org/jwestman/blueprint-compiler/"
if [[ "${PV}" == *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/${PN}.git"
else
SRC_URI="https://gitlab.gnome.org/jwestman/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
S="${WORKDIR}/${PN}-v${PV}"
KEYWORDS="~amd64 ~arm ~x86"
fi
LICENSE="LGPL-3+"
SLOT="0"
IUSE="doc test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pygobject:3[${PYTHON_USEDEP}]
')
"
BDEPEND="
${RDEPEND}
doc? (
$(python_gen_cond_dep '
dev-python/furo[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
')
)
test? (
gui-libs/gtk:4[introspection]
gui-libs/libadwaita:1[introspection]
)
"
DOCS=( CONTRIBUTING.md MAINTENANCE.md NEWS.md README.md )
src_prepare() {
default
rm ./tests/test_deprecations.py || die
}
src_configure() {
local -a emesonargs=(
$(meson_use doc docs)
)
meson_src_configure
}
src_compile() {
meson_src_compile
if use doc ; then
build_sphinx docs
fi
}
src_test() {
virtx edo "${EPYTHON}" -m unittest
}
src_install() {
meson_src_install
python_fix_shebang "${ED}/usr/bin"
python_optimize
}