net-misc/pulseaudio-dlna: revive w/ fork (add 0.6.5_p1, 9999)

Bug: https://bugs.gentoo.org/813990
Signed-off-by: Sam James <sam@gentoo.org>

net-misc/pulseaudio-dlna/Manifest

@@ -0,0 +1 @@
+DIST pulseaudio-dlna-0.6.5-1.tar.gz 712483 BLAKE2B baf1fc94f41c9ac2ca7df5c239ace36b36da4d7a40e30cf19fa630f51a0e94fa44a1ba531943ad5c4425580e4bbe68af1d5de48f5f17163783aab7b471faa72e SHA512 6fd59ac6ff0dfa98baed7a5d929c6f7d9f3539016a6383770895732f7066bc260b3d56751691573d0834a0ee29a6e542ef26e66e48c7a7af97cc84ca23ff5c2d

net-misc/pulseaudio-dlna/files/pulseaudio-dlna.desktop

@@ -0,0 +1,9 @@
+[Desktop Entry]
+Name=Pulseaudio DLNA
+Type=Application
+Comment=A lightweight streaming server which brings DLNA / UPNP and Chromecast support to PulseAudio and Linux
+Exec=sh -c "pkill pulseaudio-dlna; pulseaudio-dlna --request-timeout=30"
+Terminal=false
+Categories=
+NoDisplay=true
+StartupNotify=false

net-misc/pulseaudio-dlna/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>prometheanfire@gentoo.org</email>
+		<name>Matthew Thode</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">masmu/pulseaudio-dlna</remote-id>
+	</upstream>
+</pkgmetadata>

net-misc/pulseaudio-dlna/pulseaudio-dlna-0.6.5_p1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit desktop distutils-r1
+
+DESCRIPTION="A lightweight DLNA/UPNP/Chromecast streaming server for PulseAudio"
+HOMEPAGE="https://github.com/Cygn/pulseaudio-dlna"
+
+if [[ ${PV} == *9999 ]];then
+	EGIT_REPO_URI="https://github.com/Cygn/pulseaudio-dlna"
+	inherit git-r3
+else
+	MY_P=${PN}-${PV/_p/-}
+
+	SRC_URI="https://github.com/Cygn/pulseaudio-dlna/archive/refs/tags/${MY_P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${MY_P}
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+RDEPEND=">=dev-python/protobuf-python-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
+	>=dev-python/setproctitle-1.1.10[${PYTHON_USEDEP}]
+	>=dev-python/notify2-0.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/pyroute2-0.3.5[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3[${PYTHON_USEDEP}]
+	>=dev-python/pychromecast-10[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=dev-python/dbus-python-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/zeroconf-0.17.4[${PYTHON_USEDEP}]
+	gnome-base/librsvg[introspection]
+	x11-libs/gtk+:3[introspection]
+	|| ( media-sound/pulseaudio-daemon media-sound/pulseaudio[daemon(+)] )
+	|| (
+		|| (
+			media-video/ffmpeg[encode,mp3,opus,vorbis]
+			media-video/ffmpeg[encode,fdk,mp3,opus,vorbis]
+		)
+		(
+			media-libs/flac
+			media-sound/lame
+			media-sound/opus-tools
+			media-sound/sox
+			media-sound/vorbis-tools
+		)
+	)"
+
+python_prepare_all() {
+	sed -i -e 's/.gz//' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	domenu "${FILESDIR}"/${PN}.desktop
+}

net-misc/pulseaudio-dlna/pulseaudio-dlna-9999.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit desktop distutils-r1
+
+DESCRIPTION="A lightweight DLNA/UPNP/Chromecast streaming server for PulseAudio"
+HOMEPAGE="https://github.com/Cygn/pulseaudio-dlna"
+
+if [[ ${PV} == *9999 ]];then
+	EGIT_REPO_URI="https://github.com/Cygn/pulseaudio-dlna"
+	inherit git-r3
+else
+	MY_P=${PN}-${PV/_p/-}
+
+	SRC_URI="https://github.com/Cygn/pulseaudio-dlna/archive/refs/tags/${MY_P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${MY_P}
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+RDEPEND=">=dev-python/protobuf-python-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
+	>=dev-python/setproctitle-1.1.10[${PYTHON_USEDEP}]
+	>=dev-python/notify2-0.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/pyroute2-0.3.5[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3[${PYTHON_USEDEP}]
+	>=dev-python/pychromecast-10[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=dev-python/dbus-python-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/zeroconf-0.17.4[${PYTHON_USEDEP}]
+	gnome-base/librsvg[introspection]
+	x11-libs/gtk+:3[introspection]
+	|| ( media-sound/pulseaudio-daemon media-sound/pulseaudio[daemon(+)] )
+	|| (
+		|| (
+			media-video/ffmpeg[encode,mp3,opus,vorbis]
+			media-video/ffmpeg[encode,fdk,mp3,opus,vorbis]
+		)
+		(
+			media-libs/flac
+			media-sound/lame
+			media-sound/opus-tools
+			media-sound/sox
+			media-sound/vorbis-tools
+		)
+	)"
+
+python_prepare_all() {
+	sed -i -e 's/.gz//' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	domenu "${FILESDIR}"/${PN}.desktop
+}