x11-libs/qscintilla: remove 2.10.4

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

x11-libs/qscintilla/Manifest

@@ -1,2 +1 @@
-DIST QScintilla_gpl-2.10.4.tar.gz 2721322 BLAKE2B df50dd0a34db96dd57147ddc399d4a30751b1bb4922dc1b8b3c3c1989e810937dc8345f92128e8a606b1edc04fde4b930a424ab8344818c9899c8fe496793a77 SHA512 dee6684f68173784d098931554c839a30e129b89f980cd9704f818c44eb7023199bd3682e4b342091fa3e0ce577ec576d34046477bdd1d7fc58ca5dd2ba947a3
 DIST QScintilla_gpl-2.10.8.tar.gz 2736054 BLAKE2B 4bc7a2bc1974f8e10a96b7716a8e35d4854e9eeb8040734f99b796bddd9679ee2539f6517743689f9d7deff9ce523cdbb2f77ccd65eaadfc947dcc7a1337d918 SHA512 c0a216737dbda6bc390225196b37a43e4884c9cd67e6e81fc1b1b952683fe88dbfe7caf3c66d94a378f37502e1f08cbdf788426248e73f5f66ec65982b7652b5

x11-libs/qscintilla/qscintilla-2.10.4.ebuild

@@ -1,77 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit flag-o-matic qmake-utils
-
-MY_P=QScintilla_gpl-${PV/_pre/.dev}
-
-DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
-HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
-SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0/13"
-KEYWORDS="amd64 ~arm ppc ~ppc64 x86"
-IUSE="designer doc"
-
-DEPEND="
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtwidgets:5
-	designer? ( dev-qt/designer:5 )
-"
-RDEPEND="${DEPEND}"
-
-S=${WORKDIR}/${MY_P}
-
-src_unpack() {
-	default
-
-	# Sub-slot sanity check
-	local subslot=${SLOT#*/}
-	local version=$(sed -nre 's:.*VERSION\s*=\s*([0-9\.]+):\1:p' "${S}"/Qt4Qt5/qscintilla.pro)
-	local major=${version%%.*}
-	if [[ ${subslot} != ${major} ]]; then
-		eerror
-		eerror "Ebuild sub-slot (${subslot}) does not match QScintilla major version (${major})"
-		eerror "Please update SLOT variable as follows:"
-		eerror "    SLOT=\"${SLOT%%/*}/${major}\""
-		eerror
-		die "sub-slot sanity check failed"
-	fi
-}
-
-qsci_run_in() {
-	pushd "$1" >/dev/null || die
-	shift || die
-	"$@" || die
-	popd >/dev/null || die
-}
-
-src_configure() {
-	if use designer; then
-		# prevent building against system version (bug 466120)
-		append-cxxflags -I../Qt4Qt5
-		append-ldflags -L../Qt4Qt5
-	fi
-
-	qsci_run_in Qt4Qt5 eqmake5
-	use designer && qsci_run_in designer-Qt4Qt5 eqmake5
-}
-
-src_compile() {
-	qsci_run_in Qt4Qt5 emake
-	use designer && qsci_run_in designer-Qt4Qt5 emake
-}
-
-src_install() {
-	qsci_run_in Qt4Qt5 emake INSTALL_ROOT="${D}" install
-	use designer && qsci_run_in designer-Qt4Qt5 emake INSTALL_ROOT="${D}" install
-
-	DOCS=( ChangeLog NEWS )
-	use doc && HTML_DOCS=( doc/html-Qt4Qt5/. )
-	einstalldocs
-}