dev-python/aws-xray-sdk-python: Bump to 2.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/aws-xray-sdk-python/Manifest

@@ -1 +1,2 @@
 DIST aws-xray-sdk-python-2.6.0.gh.tar.gz 255978 BLAKE2B f43204a25027d0ec135222879bf9158aef65ba5ca948e734be0b984d8f2582741bb36d9ae0a874dffae6ffc5209e25fa1c69069c261256c3bee71a4fe717411c SHA512 17a4716467b7f6dc2912d969143e0b7c8c0b9ab15bc57f873ec415876ad2080218c3c526f4aa2c1bbf4d1caaca62eaf122c87debb45c925fd84a1bcf00ab741f
+DIST aws-xray-sdk-python-2.7.0.gh.tar.gz 265934 BLAKE2B f697c2bbe21db4b20b200ba9e9c264df81e3a6ff64d73639756d8f51a1abe0ecfaf1b852a3befde535757dfa3f75348e2eee1d5124147f04d11f5b5f20976b95 SHA512 d9ff1a190e5503f904258ac47cd7b1c686a9c74d0699f69f053df19ec7ea197da1c9c29a97624ff0758346a0dca9e3a292bf54ba3f340fcd392248602a85bfd9

dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="https://github.com/aws/aws-xray-sdk-python https://pypi.org/project/aws-xray-sdk/"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local args=(
+		# unpackaged deps
+		--ignore tests/ext/aiobotocore
+		--ignore tests/ext/pg8000
+		--ignore tests/ext/psycopg2
+		--ignore tests/ext/pymysql
+		--ignore tests/ext/pynamodb
+		--deselect tests/ext/django/test_db.py
+
+		# Internet access
+		--deselect
+		tests/test_patcher.py::test_external_file
+		--deselect
+		tests/test_patcher.py::test_external_module
+		--deselect
+		tests/test_patcher.py::test_external_submodules_full
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		--deselect
+		tests/ext/aiohttp/test_client.py
+		--ignore
+		tests/ext/httplib
+		--ignore
+		tests/ext/requests
+	)
+
+	epytest "${args[@]}"
+}