dev-python/hypothesis: Bump to 6.78.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/hypothesis/Manifest

@@ -6,3 +6,4 @@ DIST hypothesis-6.75.9.gh.tar.gz 9372102 BLAKE2B 9588536fade56f4f87f54a0dfd7c911
 DIST hypothesis-6.76.0.gh.tar.gz 9373576 BLAKE2B ed580296f163f9808597aa3a7b2ceaf1ea43431a9049ffdba229dc0f7886c8ee42829c45c98cc8ec0aae7d1f41f455f7ffd818beb1a956498ac4d676cd72b678 SHA512 2e46762a3bcc595c92eb57e65b2c7ef07062df1c393033efd2cb6b3c774ecbbe41f672e7b6c63ca0e8afb732c0f5308dddd6908bc2f43eab5c0713a6d688d5f4
 DIST hypothesis-6.77.0.gh.tar.gz 9376438 BLAKE2B 2c80427a43481fbc837042c8481e56f1186fa9026c15902f489b1d26cda216f33df6da2025e37d8b37676047d7a8be1f0aea686ec0d2d18178d14e5e8f08f24c SHA512 17c1a0d1b00c0bd9a4373c5cafa7f58f4f6c85a85a107f4afff7064b52280a21210502c555291a580c81c1085f7c5fdd9db91391b29b2af6e476c83f4838fe1a
 DIST hypothesis-6.78.1.gh.tar.gz 9376599 BLAKE2B c0998212067e947af71f17aa5f76609ed71cf57cf4d71418329ec92ca663b202bc3c8d09936e147304744d81d01f9ba0ae5f5cf369fe04cbcb95c351a3a6cd06 SHA512 5491dfce1a8a25288aca345a6a6f8b88557b3dc2a08773ee2aa10d133d9b44b9bddb4d7584ac99046a006f3d9fb85713b6b38f5cc635ddc437c8fb4bbe58a866
+DIST hypothesis-6.78.2.gh.tar.gz 9376858 BLAKE2B 8bbc6e373a9dd67b47922c4ba9f938f90d154a945f7142d07304db11b5b4e4d53b21605e4f7be24fb413153a2edf9c54bec01409a72abfb8fb31b43c87836ede SHA512 65ea4396365a3f4f1740d61cbcdf0eb380f99c133d582b56ee3e557bcc4da0d329ac832b38dad64c5e5fb7afcace55a17cc22fbb15ea1751508488983a1d7cef

dev-python/hypothesis/hypothesis-6.78.2.ebuild

@@ -0,0 +1,104 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..11} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_12 pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_IGNORE=()
+	local EPYTEST_DESELECT=(
+		# these tests can randomly fail with RecursionError when run
+		# in parallel
+		# https://github.com/HypothesisWorks/hypothesis/issues/3671
+		hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types
+		hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types_with_defaults
+	)
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				hypothesis-python/tests/cover/test_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}